Calculating $\left\langle\operatorname{Aut}(G),\alpha\right\rangle$ with GAP.

Question

Let $ G $ be a arbitary group and for $x\in G$, $\alpha:x‎\longrightarrow x^{-1}$ be a bijective function so that $\alpha \not\in \operatorname{Aut}(G)$. I want to calculate $\left\langle\operatorname{Aut}(G),\alpha\right\rangle$ with GAP, for example for $G=S_3$ we have $\left\langle\operatorname{Aut}(S_3),\alpha\right\rangle=\left\langle S_3,\alpha\right\rangle=S_3\rtimes‎‎‎ C_2$, thanks in advance.

Answer 1

View $\operatorname{Aut}(G)$ as a subgroup of the group of permutations on $G$.

PermFromHom := hom -> PermListList( AsSet( Source( hom ) ), List( AsSet( Source(hom) ), g -> g^hom ) );

HomFromPerm := function( g, perm ) return GroupHomomorphismByImages( g, g, GeneratorsOfGroup( g ), List( GeneratorsOfGroup(g), x -> AsSet(g)[ Position( AsSet( g ), x )^perm ] ) ); end;

You can convert $\operatorname{Aut}(G)$ either using these functions:

autAsPerm := Group( List( GeneratorsOfGroup( AutomorphismGroup( G ) ), PermFromHom ) );

or using the holomorph:

regAsPerm := Image( RegularActionHomomorphism( G ) );
holAsPerm := Normalizer( SymmetricGroup ( Size( G ) ), regAsPerm );
autAsPerm := Stabilizer( holAsPerm, 1 );

You can add permutations to a permutation group using ClosureGroup:

invAsPerm := PermListList( AsSet(G), List( AsSet(G), x -> x^-1 ) );
ainAsPerm := ClosureGroup( autAsPerm, invAsPerm );