Can GAP compute this 16-dimensional representation of AlternatingGroup(6)?

Question

I am interested in a particular 16-dimensional representation of $A6$, the alternating group on 6 things. I first construct an amalgam, gamma, of two copies of SymmetricGroup(4):

F:=FreeGroup(["s1","s2","s3","t1","t2","t3"]); 
AssignGeneratorVariables(F); 
rel:=Union(
[s1^2,s2^2,s3^2,s1*s3*s1^-1*s3^-1,(s1*s2)^3,(s2*s3)^3],
[t1^2,t2^2,t3^2,t1*t3*t1^-1*t3^-1,(t1*t2)^3,(t2*t3)^3],
[s1*s3*(t1*t3)^-1, s1*(t2*t3*t1*t2)^-1, s2*s3*s1*s2*t1^-1]);
gamma:=F/rel;  #an amalgam of two SymmetricGroup(4)

Next, I find an epimorphism from gamma onto $A6$ and take the kernel, $K$:

A6:=AlternatingGroup(6);
QA:=GQuotients( gamma, A6);
f:=QA[1]; #an epimorhism from gamma onto A6
K:=Kernel(f);
GeneratorsOfGroup(K);
AbelianInvariants(K);  # the abelianization of the kernel K of f is free abelian of rank 16
Size(AbelianInvariants(K));

Note that the abelian quotient, $K_{ab}$, of $K$ is free abelian of rank 16.

Now A6 acts (up to inner automorphisms) on $K$ and $K_{ab}$. For instance, the generators of A6 act on K.1 as follows

pre:= List(GeneratorsOfGroup(A6),  a -> PreImagesRepresentative(f,a) );
act:=List(pre, u -> MappingByFunction(K,K, x -> x^u));
List(act, a -> a(K.1));

I would like to know the 16-dimensional representations of $A6$ given by the action of $A6$ on $K_{ab}$ or $K_{ab} \otimes Z/2$.

My question is: Can GAP compute the $(16 \times 16)$-matrices of this representation of $A6$ (over the integers or the integers mod 2)?

Answer 1

Take the maximal abelian Quotient of $Q$. (I'm doing this in the development version. It is possible that Version 4.12 will act a bit more clunky):

gap> ma:=MaximalAbelianQuotient(K);;
gap> Q:=Range(ma);
<fp group of size infinity on the generators
[ f1, f2, f3, f4, f5, f6, f7, f8, f9, f10, f11, f12, f13, f14, f15, f16 ]>
gap> gens:=GeneratorsOfGroup(Q);
[ f1, f2, f3, f4, f5, f6, f7, f8, f9, f10, f11, f12, f13, f14, f15, f16 ]

Now we compute, for every Generator of gamma, the action on the generators of $Q$: take $q\in Q$, preimage in $\Gamma$, act by conjugation, map back into $Q$:

gap> act:=List(GeneratorsOfGroup(gamma),x->List(GeneratorsOfGroup(Q),
> y->ImagesRepresentative(ma,PreImagesRepresentative(ma,y)^x)));

and convert to vector/matrix form (writing additively):

act:=List(act,x->List(x,y->ExponentSums(UnderlyingElement(y))));;

The command UnderlyingElement here simply takes the free group word representing the finitely presented group element.

These matrices give you a $\mathbb{Z}$-representation of the factor, i.e. the matrices you asked for:

gap> List(act,Order);
[ 2, 2, 2, 2, 2, 2 ]
gap> Size(Group(act));
360

Reduce modulo $2$:

amo:=List(act,x->ImmutableMatrix(GF(2),x*Z(2)^0));

Verify irreducibility (but not absolute irreduciblility):

gap> module:=GModuleByMats(amo,GF(2));;
gap> MTX.IsAbsolutelyIrreducible(module);
false
gap> MTX.IsIrreducible(module);
true

Let me close with a shameless advertisement for my own work (Dietrich,Hulpke, Universal covers of finite groups. J. Algebra 569(2021), 681–712.) and the associated code at https://github.com/hulpke/hybrid : We can calculate the largest extension by a semisimple module in characteristic 2 that is still quotients of $\Gamma$. This gives you the actual extension $2^{16}.A_6$:

gap> # load the extra code
gap> lift:=LiftQuotientHybrid(f,2);
Irreducible Module 1, dim=1
idx=[ 1 ]
Cover of size 46080 does not extend
Irreducible Module 2, dim=4
idx=[ 1 .. 4 ]
Cover of size 27200830941329156430888960 does not extend
Irreducible Module 3, dim=4
idx=[ 1 .. 4 ]
Cover of size 27200830941329156430888960 does not extend
Irreducible Module 4, dim=16
idx=[ 1, 2, 3, 4, 5, 6, 7, 8 ]
Cover of size [big] extends by dimension 16
Now subdirect covers, extend by [ 0, 0, 0, 16 ] as [ 16 ] to 16
[ s1, s2, s3, t1, t2, t3 ] -> [ <F1^-1*F4>, <F2*F4>, <F1*F2*F1*F4>,
  <F1^-1*F2*F1>, <F1*F3*F2*F1^-1*F4*F3*f1*f2*f4*f7*f9*f10*f13*f15*f16>,
  <F2> ]