Commutator of two elements in group algebra $\mathbb F_{5}D_{30}.$

Question

I want to understand how to find the commutator of two elements in the group algebra $\mathbb{F}_{5}D_{30}$ using GAP. Additionally, I would like to determine the nilpotency class of the nilpotent group $1+J(\mathbb{F}_{5}D_{30})$ which is a subgroup of unit group, where $J(\mathbb{F}_{5}D_{30})$ represents the Jacobson radical of the group algebra $\mathbb{F}_{5}D_{30}$. In this context, $D_{30}=\{{a,b\mid a^{15}=b^2=1, bab=a^{-1}}\}$ denotes the dihedral group of order $30.$ Here, $\mathbb{F}_{5}$ is a field of characteristic $5$, consisting of $5$ elements.

It is already known that $({1+J(\mathbb{F}_{5}D_{30})})^5=1$ since $(J(\mathbb{F}_{5}D_{30}))^5=0$. The nilpotency class of $1+J(\mathbb{F}_{5}D_{30})$ has been determined to be $4$ through calculations, but I would like to verify this using GAP.

How to demonstrate the nilpotency class of the nilpotent group $1+J(\mathbb{F}_{5}D_{30})$ as $4$, and to compute the commutator $(x,y)=x^{-1}y^{-1}xy$ where $x=a^3$ and $y=1+4b+a^9b$?

I only know how to define group algebra in GAP.

gap> LoadPackage("laguna");
true
gap> G:=DihedralGroup(30);;
gap> FG:=GroupRing(GF(5),G);
<algebra-with-one over GF(5), with 3 generators>
gap> IsGroupAlgebra(FG);
true
gap> RadicalOfAlgebra(FG);
<algebra of dimension 24 over GF(5)>

I am not familiar with GAP and would appreciate a thorough explanation of the example. If someone explains this example in detail, it will greatly assist me in applying the same methodology to any group algebra. Your assistance is greatly appreciated. Thank you in advance.

Answer 1

I think this can be done reasonably easily in the matrix world.

Start with the regular permutation representation:

gap> G:=DihedralGroup(30);;
gap> rep:=RegularActionHomomorphism(G);;
gap> H:=Image(rep,G);
Group([ (1,2)(3,30)(4,24)(5,29)(6,21)(7,28)(8,27)(9,18)(10,26)(11,25)(12,15)
  (13,23)(14,22)(16,20)(17,19), (1,3,7,4,8,13,9,14,19,15,20,25,21,26,29)
  (2,5,10,6,11,16,12,17,22,18,23,27,24,28,30), (1,4,9,15,21)(2,6,12,18,24)
  (3,8,14,20,26)(5,11,17,23,28)(7,13,19,25,29)(10,16,22,27,30) ])

Then form matrices and the algebra generated by them:

gap> mats:=List(GeneratorsOfGroup(H),x->PermutationMat(x,30,GF(5)));
gap> A:=Algebra(GF(5),mats);
<algebra over GF(5), with 3 generators>
gap> R:=RadicalOfAlgebra(A);
<algebra of dimension 24 over GF(5)>

Form a group from a basis of the radical

gap> gens:=List(Basis(R),x->x+One(A));;
gap> B:=Group(gens);
<matrix group with 24 generators>

You could calculate commutators in this matrix representation. But GAP can do more.

Now we use the recog package. Slight caveats: 1) This has a number of dependencies, and might not be entirely trivial to install. 2) It still lacks verificationm, and so we need to check that the resulting group order is correct:

gap> LoadPackage("Recog");
true
gap> Size(RecognizeGroup(B));
59604644775390625
gap> 5^24;
59604644775390625

Since the group must be solvable, we now can use my matgrp package to convert to a pc presentation:

gap> LoadPackage("matgrp");
true
gap> ff:=FittingFreeLiftSetup(B);;
gap> pc:=Image(ff.pcisom);
<pc group of size 59604644775390625 with 24 generators>

and get a pc presented version of the group. (Again, check that the order is correct!) In this represenation we can easily calculate the nilpotency class:

gap> NilpotencyClassOfGroup(pc);
4

You can compute the commutator of certain elements through the matrices. Say, you want to compute the commutator of $1+f_2+f_2f_3$ with $1+f_1f_2^2-f_1f_2^2f_3^4$, you would compute a basis of the algebra, corresponding to elements:

gap> elms:=Elements(G);
[ <identity> of ..., f1, f2, f3, f1*f2, f1*f3, f2^2, f2*f3, f3^2, f1*f2^2,
  f1*f2*f3, f1*f3^2, f2^2*f3, f2*f3^2, f3^3, f1*f2^2*f3, f1*f2*f3^2, f1*f3^3,
  f2^2*f3^2, f2*f3^3, f3^4, f1*f2^2*f3^2, f1*f2*f3^3, f1*f3^4, f2^2*f3^3,
  f2*f3^4, f1*f2^2*f3^3, f1*f2*f3^4, f2^2*f3^4, f1*f2^2*f3^4 ]
gap> bas:=List(elms,x->PermutationMat(ImagesRepresentative(rep,x),30,GF(5)));;
gap> bas:=Basis(A,bas);;

Then find the matrices for $c$ and $d$ in there and form the two elements:

gap> f1mat:=bas[Position(elms,G.1)];;
gap> f2mat:=bas[Position(elms,G.2)];;
gap> f3mat:=bas[Position(elms,G.3)];;
gap> elm1:=f1mat^0+f2mat+f2mat*f3mat;;
gap> elm2:=f1mat^0+f1mat*f2mat^2-f1mat*f2mat^2*f3mat^4;;

Then compute coefficients of the commutator:

gap> co:=List(Coefficients(bas,Comm(elm1,elm2)),Int);
[ 0, 2, 4, 0, 4, 0, 2, 4, 3, 2, 2, 3, 0, 3, 3, 2, 3, 0, 2, 1, 0, 0, 1, 0, 3, 3, 3, 0, 3, 3 ]
gap> sel:=Filtered([1..Length(elms)],x->co[x]<>0);
[ 2, 3, 5, 7, 8, 9, 10, 11, 12, 14, 15, 16, 17, 19, 20, 23, 25, 26, 27, 29,
  30 ]
gap> List(sel,x->[co[x],elms[x]]);
[ [ 2, f1 ], [ 4, f2 ], [ 4, f1*f2 ], [ 2, f2^2 ], [ 4, f2*f3 ], [ 3, f3^2 ],
  [ 2, f1*f2^2 ], [ 2, f1*f2*f3 ], [ 3, f1*f3^2 ], [ 3, f2*f3^2 ],
  [ 3, f3^3 ], [ 2, f1*f2^2*f3 ], [ 3, f1*f2*f3^2 ], [ 2, f2^2*f3^2 ],
  [ 1, f2*f3^3 ], [ 1, f1*f2*f3^3 ], [ 3, f2^2*f3^3 ], [ 3, f2*f3^4 ],
  [ 3, f1*f2^2*f3^3 ], [ 3, f2^2*f3^4 ], [ 3, f1*f2^2*f3^4 ] ]

and you see that it starts with $2f_1+4f_2+4f_1f_2+\cdots$ and so on.