Computing the rank of a specific group

Question

The rank of a group is the minimum number of elements needed to generate the group. In general, the rank of a group is not algorithmically computable for finitely presented groups. I have a specific group $G$ (given by a presentation) that I believe has rank 4 and not smaller rank.

Ideally, I could just plug my group into some preexisting software to approach this question - does anyone know of such software?

Here is how I (not knowing any better) would approach this. I would like to find a surjection $G \to H$ where $H$ is say a finite group of rank 4. I would like to generate a list of some (hopefully manageably sized) such finite groups $H$ and start going through the list and testing each such group to see if there is a surjection $G \to H$. How can I easily get my hands on a list of rank 4 finite groups?

Edit:

Here is the group: $$ \langle u,v,w,x,y,z : uxy^{−1}v^{−1}w, uyz^{−1}w^{−1}x, uzv^{−1}x^{−1}y,uvw^{−1}y^{−1}z,uwx^{−1}z^{−1}v, vxzwy \rangle $$

(Edit by Derek Holt) And here it is again in a form suitable for copying and pasting:

< u,v,w,x,y,z | 
u*x*y^-1*v^-1*w, u*y*z^-1*w^-1*x,
u*z*v^-1*x^-1*y, u*v*w^-1*y^-1*z,
u*w*x^-1*z^-1*v, v*x*z*w*y >

Answer 1

There are many, many finite groups of rank 4, and just very few will be quotients of your group. I think it will be much better to compute finite quotients of your group G (using so-called quotient algorithms, and then try to show that these quotients must have rank 4.

Here are some first steps in GAP. Define the group, and remove redundant generators (that will speed up things):

gap> f:=FreeGroup("u","v","w","x","y","z");;
gap> rels:=ParseRelators(f,"uxYVw,uyZWx,uzVXy,uvWYz,uwXZv,vxzwy");
[ u*x*y^-1*v^-1*w, u*y*z^-1*w^-1*x, u*z*v^-1*x^-1*y, u*v*w^-1*y^-1*z,
  u*w*x^-1*z^-1*v, v*x*z*w*y ]
gap> g:=f/rels;
<fp group on the generators [ u, v, w, x, y, z ]>
gap> sim:=IsomorphismSimplifiedFpGroup(g);
[ u, v, w, x, y, z ] -> [ u, v, v*y*x^-1*u^-1, x, y, u*x*y^-1*v^-1*x*u*y ]
gap> h:=Image(sim);
<fp group on the generators [ u, v, x, y ]>

Now we find the largest abelian quotient:

gap> AbelianInvariants(h);
[ 5, 5, 5 ]

This gives us a minimum of 3 generators. Not good enough. Try for another quotient. We intersect all subgroups of index <=6, and take the quotient by the core of their intersection:

gap> l:=LowIndexSubgroups(h,6);;
gap> k:=Intersection(l);;
gap> Index(h,k);
2863692069181011181015005016041480695253565440000000000
gap> q:=DefiningQuotientHomomorphism(k);;
gap> p:=Image(q);
<permutation group of size 366552584855169431169920642053309528992456376320000000000000000000000000000000000000 with 4 generators>

This is a gargantuan quotient, lets look at its structure. After some playing around, we find that it is a direct product

gap> res:=PerfectResiduum(p);;
gap> Index(p,res);
125
gap> z:=Centre(p);
<permutation group of size 125 with 3 generators>
gap> Size(Intersection(z,res));
1
gap> p=ClosureGroup(res,z);
true

So it is a direct product of $5^3$ with a perfect group. It turns out to also be a direct product and here an ad-hoc decomposition works better than the generic method:

gap> dom:=MovedPoints(res);;
gap> o:=Orbits(res,dom);;
gap> Length(o);
34
gap> Collected(List(o,Length));
[ [ 5, 7 ], [ 6, 27 ] ]
gap> os:=List(o,x->Stabilizer(res,Difference(dom,x),OnTuples));;
#G  FULL  504889/  55606kb live  2877911/ 333718kb dead    50312/ 131072kb free
#G  FULL  520120/  61305kb live   210758/  64281kb dead    44376/ 131072kb free
gap> Collected(List(os,Size));
[ [ 60, 7 ], [ 360, 27 ] ]
gap> ForAll(os,x->IsNormal(p,x));
true
gap> ForAll(os,IsSimpleGroup);
true
gap> n:=TrivialSubgroup(res);;for i in os do n:=ClosureGroup(n,i);od;
gap> n=res;
true

So we have a quotient $5^3\times A_5^7\times A_6^{27}$. Now (see https://mathoverflow.net/questions/265260/how-many-generators-does-a-direct-product-of-alternating-groups-need ) the minimal generator number of this moduct is the maximum of the minimal generator number for each of the direct powers. By a famous theorem of Hall, for a finite group $G$, the maximal $m$ such that $G^m$ is $k$-generated is $\phi_k(G)/|Aut(G)|$, where $\phi_k(G)$ is the number of $k$-generator ordered tuples. We can calculate this in GAP as number of quotients of a free group of rank $k$:

gap> Length(GQuotients(FreeGroup(2),AlternatingGroup(5)));
19
gap> Length(GQuotients(FreeGroup(2),AlternatingGroup(6)));
53

Thus the three "coprime" direct factors are all $3$-generated, and thus the whole group, and we would need a different quotient.

Investigating further, however did not find more fruitful quotients. Thus I'm sceptical about thelikeliness of this approach being successful.