Free Vertices in GAP

Question

How can we program this kind pf permutations in GAP?

Let we have and Extended Triangle Group $(2,3,7)=<x^2=t^2=y^3=(xt)^2=(yt)^2=(xy)^7=1>$

We have subgroup of Index 14 having permutation representation

$x=(3,4)(5,7)(6,8)(9,12)(10,13)(11,14)$

$y=(1,2,3)(4,5,6)(7,9,10)(8,11,12)$

t is the axis of symmetry in the Coset Digram as cited above

I want to find the i free vertices of this group means points fixed for x and moved for y, but are contiguous.

Here in this example points 1 and 2 are fixed for x and moved for y, moreover are consecutive to each other.

So here we have i=2 free vertices.

How can I program this in GAP.

I am starting like this

>FreeVertices := function(p,q,r,n)
>local x,t,y,f,g,m,hlist,h,j,k,o,l,permslist,perms,points;
>f := FreeGroup(3);
>g := f/[f.1^p,f.2^2,f.3^q,(f.1*f.2)^2,(f.2*f.3)^2,(f.1*f.3)^r];
>h := Filtered(LowIndexSubgroupsFpGroup(g,n),i->Index(g,i)=n);
>points:=[];
>o := [];
>m:=[];
> x := List(CosetTable(g,h[1]){[1]},PermList)[1];
> t := List(CosetTable(g,h[1]){[3]},PermList)[1];
> y := List(CosetTable(g,h[1]){[5]},PermList)[1];
>Print("x =",x,"\n","y =",y,"\n","t =",t,"\n");
>for j in MovedPoints(y) do
>if j=j^x then 
>Add(points,[j,j^x]); #Collection of Points in y that are fixed for x.
>fi;
>od;
>Print("Points =",points,"\n");
>k:=Length(points);
>for m in points do
>l:=m^y;
>Add(o,l); # finding the images of the previous list under y 
>od;
>Print("Points fixed for x and their images under y =",o,"\n");
>end;  

Answer 1

I hope that I've got right the question boiled down to two permutations, and you will be able to incorporate this example in your code. I am not commenting those parts of the question which are outside that scope, but please check my concerns about CosetTable usage expressed in the comments. If this example does not do what you had in mind, or if you need further comments, please ask.

---

Question (short version)

Let $G$ be a permutation group acting on the set $S$, and let $G$ is generated by two permutations $x$ and $y$. Let $M$ be the subset of $S$ consisting of points fixed under the permutation $x$. How to calculate images of points from $M$ under the permutation $y$ and then check that $M^y$ contains in some cycle of $y$?

Answer

First, two permutations from one of your comments:

gap> x:=(1,2,3)(6,7)(9,10,11);                            
(1,2,3)(6,7)(9,10,11)
gap> y:=(4,5,8,10)(1,3,2,6);                              
(1,3,2,6)(4,5,8,10)

Now calculate which points from [1..11] are fixed under x (we obtain 11 as the maximum of the largest moved points of x and y, so we don't actually need a group generated by these elements):

gap> xfixes:=Filtered([1..Maximum(List([x,y],LargestMovedPoint))],i->i^x=i);
[ 4, 5, 8 ]

Indeed, it is not obvious from the GAP manual how to convert a permutation into a list of cycles. One could write one's own code for that, but perhaps the following trick would be faster:

gap> ycycles:=CyclesOfTransformation(AsTransformation(y));
[ [ 1, 3, 2, 6 ], [ 4, 5, 8, 10 ], [ 7 ], [ 9 ] ]

(Note that CyclesOfTransformation is not available in GAP 4.6 and earlier releases).

Now we can check whether there is a cycle which involves all points from a given subset:

gap> ForAny(ycycles, c -> IsSubset(c,xfixes)); 
true
gap> ForAny(ycycles, c -> IsSubset(c,[1,2,3]));
true
gap> ForAny(ycycles, c -> IsSubset(c,[1,4]));  
false

So, this works correctly. Now we are ready to calculate the images of elements of xfixes under y:

gap> xy:=List(xfixes, a -> a^y);
[ 5, 8, 10 ]

And even check in the same way as before that y has a cycle which involves 5, 8 and 10:

gap> ForAny(ycycles, c -> IsSubset(c,xy));   
true

But actually this last step is not needed, since if there is a cycle containing all points from xfixes, then clearly this cycle will also contain their images.