GAP for Design Theory

Question

In journal titled "Unitals, Projective Planes and Other Combinatorial Structures Constructed from the Unitary Groups U(3,q), q=3,4,5,7", in the picture attached,

GAP used there, the word: "Using GAP[11], one can check that ........."

How to code those in GAP? If you know anything (like tutorial in GAP or anything) or the code for those, please inform me, even a little information, really means much to me, thank you.

note: if i ask the source code to the author of journal, is it croos ethic code in knowledge? or if not, will the author give me the source code?

Thank You,

Sincerely, M. Reza H.

Answer 1

This is in fact not too difficult. Checking the description of the maximal subgroups $H_1$ and $H_5$, it becomes clear that by "unitary group", the author means "projective special unitary group" (as opposed to the other varieties of unitary group). With this information, you can go ahead and just type the following GAP code into the REPL loop.

gap> G := PSU(3,5);
<permutation group of size 126000 with 2 generators>
gap> ccl := ConjugacyClassesMaximalSubgroups(G);;
gap> List(ccl, c -> Size(c));
[ 50, 50, 50, 126, 175, 175, 175, 525 ]

This lists the sizes of the conjugacy classes of the maximal subgroups of $G$, hinting to the fact that the paper talks about representatives from the fourth and eigth conjugacy class.

gap> List(ccl, c -> Size(c[1]));
[ 2520, 2520, 2520, 1000, 720, 720, 720, 240 ]

And this definitely confirms that hint, so we select those two conjugacy classes and choose any representatives of them as our groups $H_1$ and $H_5$.

gap> Cl1 := ccl[8];;
gap> Cl5 := ccl[4];;
gap> H1 := Cl1[1];
<permutation group of size 240 with 2 generators>
gap> H5 := Cl5[1];
<permutation group of size 1000 with 2 generators>

It is sufficient here to select just one representative from the conjugacy class of $H_1$ when categorizing and counting intersections:

gap> intersections := List(Cl5, c -> Intersection(H1, c));;

Next we filter out all those intersections isomorphic to a $\mathbb{Z}_2$ and count and describe the remaining ones:

gap> largeIntersections := Filtered(intersections, i -> Size(i) <> 2);;
gap> Size(largeIntersections);
6
gap> List(largeIntersections, i -> StructureDescription(i));
[ "C5 : C8", "C5 : C8", "C5 : C8", "C5 : C8", "C5 : C8", "C5 : C8" ]

---

Added on Nov-08-2017:

Now, we set up our set $\mathcal{S}$ of the $126$ subsets $S_i$ of the conjucacy class of $H_1$ intersecting a given conjugate of $H_5$ in a group of type C5:C8:

gap> S := List(Cl5, c5 -> Filtered(Cl1, c1 -> Size(Intersection(c1, c5)) <> 2));;
gap> Size(S);
126

And finally, we verify that any two distinct such $S_i$ intersect in a set containing just one element:

gap> Comb := Combinations([1..126], 2);;
gap> Filtered(Comb, c -> Size(Intersection(S[c[1]], S[c[2]])) <> 1);
[  ]

Again, for an introduction to GAP, I recommend you read the official tutorial and referenc manual which can both be found at http://www.gap-system.org/Doc/manuals.html.