Geometric Interpretation and Graph using Maple

Question

1. Use the formal definition of the derivative to find the derivative of $y=5x^2$ at $x=-1$.
2. Show that the point $(-1,5)$ is on the graph of $y=5x^2$ and find the equation of the tangent line at the point $(-1,5)$.
3. Graph $y=5x^2$ and the tangent line at the point $(-1,5)$ in the same coordinate system.

For the first question, I have already managed to get the answer. But I have no idea where to start with question 2 and 3 since I have never actually learned Maple. How should the Maple command be like in order to get the graph?

Please help!

Answer 1

1.)

   y := proc (x) options operator, arrow; 5*x^2 end proc;
   eval(diff(y(x), x), x = -1);

2.)

for $x=-1$ is $y=5$

   eval(y(x), x = -1);
   solve(eval(Y-y = (diff(y(x), x))*(X-x), [x = -1, y = 5]), {Y});

Equation of the tangent line is: $y = -10 x-5$

3.)

   plot([5*x^2, -10*x-5], x = -2 .. 2);

Screenshot:

Answer 2

See whether the results of these steps make sense to you, in terms of what you know of the definition of the derivative and the equation of a line (obtained from its slope and a single x-y point).

restart;
defn := Limit( ( f(x+t) - f(x) )/t, t=0 );

y := x -> 5*x^2;

eval(defn, f=y);
value( eval(defn, f=y) );
dy := unapply( value( eval(defn, f=y) ), x);

dy(-1);

y(-1);

tang_line := ( Y - y(-1) ) = dy(-1) * ( X - (-1) );
isolate(tang_line,Y);
rhs( isolate(tang_line,Y) );
tang_fun := unapply( rhs( isolate(tang_line,Y) ), X );

plots:-display(
  plot( y(x), x=-2..0, color=red ),
  plot( [[-1, 5]], color=black,
        style=point, symbol=solidcircle, symbolsize=15 ),
  plot( tang_fun(x), x=-2..0, color=blue )
);