How to solve calculus integration problem using Maple?

Question

May I know if it is possible to solve these problems using Maple? ( I've tried it by hand but I would like to know if there are alternatives)

1. In triangle ABC, M is the point on BC such that the angle of BAC = 4 MAC Given that a(1,2) ,B(2,5), C(3,3).Find the coordinates of M.
2. Given the equation y^2=x^3 + x^2 , Compute the length of the curve as well as find the area of surface formed by revolving the curve about the x axis.

Thank You!

Answer 1

Your first question is not calculus; it's analytic geometry. Maple can do the problem rather directly with its geometry package. The steps are to define the triangle and to bisect $\angle BAC$ twice. In the code below, $P$ is the point where the bisector of a $\angle BAC$ intersects $\overline{BC}$.

restart:
G:= geometry:
G:-triangle(ABC, [G:-point(A,1,2), G:-point(B,2,5), G:-point(C,3,3)]):
G:-bisector(AP, A, ABC, P): 
G:-bisector(AM, A, G:-triangle(APC, [A, P, C]), M):
G:-coordinates(M);

Maple responds:

[(3*sqrt(2)*sqrt(2+sqrt(2))+2+3*sqrt(2))/(sqrt(2)+1+sqrt(2)*sqrt(2+sqrt(2))), (3*sqrt(2)*sqrt(2+sqrt(2))+5+3*sqrt(2))/(sqrt(2)+1+sqrt(2)*sqrt(2+sqrt(2)))]

Simplify and get a decimal approximation:

evala(%);

[4+sqrt(2)-sqrt(2)*sqrt(2+sqrt(2)), 1-2*sqrt(2)+2*sqrt(2)*sqrt(2+sqrt(2))]

evalf(%);

[2.801087633, 3.397824734]

Draw a diagram of the situation.

G:-draw(
   [ABC(printtext= true), AP, AM(printtext= true)],
   view= [0.5..3.5, 1.5..5.5], scaling= constrained
);

Verify that $\angle BAC$ has four times the measure of $\angle MAC$.

Angle:= proc(A,B,C)
uses V= geometry:-coordinates;
local BA:= <V(A)-V(B)>, BC:= <V(C)-V(B)>;
     arccos(BA.BC/sqrt(BA.BA*(BC.BC)))
end proc:

simplify(Angle(B,A,C) / Angle(M,A,C));

(1/4)*Pi/arccos((1/2)*sqrt(2+sqrt(2+sqrt(2))))

evalf[15](%);

3.99999999999995