Is it possible to say that if a A is a set of elements of a semigroup S, there exists some other semigroups on the alphabet A?

Question

Suppose we have a finite semigroup, its element's set is A = {1,2,...n}, can we get some other semigroups whose element's set is A too ?

Answer 1

1160 is the number of semigroups of order $5$ up to isomorphism or anti-isomorphism. Anyway, the following GAP code does what you want if a few seconds.

LoadPackage("smallsemi");
S5 := SymmetricGroup(5);
allsg := [];
for i in [1..1160] do
  Print("Processing semigroup number ",i,"\n");
  s := SmallSemigroup(5, i);
  ls := List(s);
  #construct multiplication table of this semigroup.
  table := List(ls, x -> List(ls, y -> Position(ls,x*y)));
  tabs := [];
  for g in S5 do
    #Apply g to rows and columns of table to get isomorphic semigroup
    Add(tabs, List([1..5], x -> List([1..5], y -> table[x^g][y^g]^(g^-1))));
  od;
  #remove duplicates
  tabs := Set(tabs);
  #see if opposite semigroup is in list - if not add it and images under S5
  otable := TransposedMat(table);
  if not otable in tabs then
    tabs := Concatenation(tabs, List(tabs, x->TransposedMat(x)));
  fi;
  allsg := Concatenation(allsg, tabs);
od;

After running this, we get, as expected:

gap> Length(allsg);     
183732