Is there a rank 3 boolean interval [H;G] with G simple group?

Question

Let $[H;G]$ be an interval of finite groups.

The rank $n$ boolean lattice $B_{n}$ is the subset lattice of $\{1,2, \dots , n\}$.
For example, for $m = p_1p_2 \dots p_n$ square free, $[1;\mathbb{Z}/m]$ is a rank $n$ boolean lattice.
The lattice $B_{3}$ is the following:

Question: Is there a rank $3$ boolean interval $[H;G]$ with $G$ simple group?

Remark: GAP has found no example for $\vert G \vert <5000$.

Answer 1

In $S_n$, the subgroup $S_a\times S_b$, $a+b=n$, $a\not=b$ is maximal. So taking the three maximal subgroups as stabilizers in $S_n$ of disjoint sets of different cardinalities looks like a good place to start for such configurations. Indeed, searching through alternating groups finds the following example (though it is not of this kind that motivated searching through alternating groups...):

If you take $G=A_8$ and $H=t_8n_{29}=[2^3]D(4)$ (of order 64) the condition is satisfied (as found by an explicit computation in GAP:

g:=AlternatingGroup(8);
u:=TransitiveGroup(8,29);
int:=IntermediateSubgroups(g,u);

In case anyone cares, and to satisfy the (gap)-tag, here is the code I used for searching. It only tests for 6 intermediate subgroups, the final test of the groups then is a hand-inspection of the result of IntermediateSubgroups.

test:=function(G)
  local m,allmax,m2,m3,mm,i,j,int;
  m:=MaximalSubgroupClassReps(G);
  allmax:=MaximalSubgroups(G);
  Print("|m|=",Length(m),"\n");
  Print("|allmax|=",Length(allmax),"\n");
  m2:=Union(List(m,x->Filtered(MaximalSubgroupClassReps(x),
      y->Number(allmax,z->IsSubset(z,y))=2)));
  Print("|m2|=",Length(m2),"\n");
  m2:=List(SubgroupsOrbitsAndNormalizers(G,m2,false),x->x.representative);
  Print("|m2|=",Length(m2),"\n");
  m3:=[];
  for i in [1..Length(m2)] do
    mm:=Filtered(MaximalSubgroupClassReps(m2[i]),
      y->Number(allmax,z->IsSubset(z,y))=3);
    Print(i,", |mm|=",Length(m2),"\n");
    for j in mm do
      int:=IntermediateSubgroups(G,j);
      if Length(int.subgroups)=6 and Length(int.inclusions)=12 then
        Print("found!\n");
        Add(m3,j);
      fi;
    od;
  od;
  m3:=List(SubgroupsOrbitsAndNormalizers(G,m3,false),x->x.representative);
  return m3;
end;