Isomorphism and GAP

Question

Suppose $G$ and $H$ are two finite groups such that $\frac{G}{Z(G)}\cong\frac{H}{Z(H)}$. The Command $K:=IsomorphismGroups(\frac{G}{Z(G)},\frac{H}{Z(H)})$, in GAP, gives all the isomorphism from $\frac{G}{Z(G)}$ onto $\frac{H}{Z(H)}$. I have two questions:-

1. If $\chi\in K$, then how to apply the map $\chi$ on any element $x\in \frac{G}{Z(G)}$ in GAP? I have tried $\chi(x)$ and $x^\chi$, both are not working. I have not seen anything like this as well in the GAP manual.

2. Suppose $\chi(gZ(G))=y$. Then $y=hZ(H)$ for some $h\in H$. How to extract the element $h$ in $y$ in GAP?

Thank you for any help.

Answer 1

To start off, let me correct you on IsomorphismGroups. It does not give you all isomorphisms, but rather it gives you one isomorphism (if it exists, otherwise it returns fail).

gap> G := Group( [ (2,8)(3,7)(5,6), (1,2,3,5,4,6,7,8) ] );;
gap> H := QuaternionGroup( 16 );;
gap> p := NaturalHomomorphismByNormalSubgroup( G, Centre( G ) );;
gap> pG := Image( p );;
gap> q := NaturalHomomorphismByNormalSubgroup( H, Centre( H ) );;
gap> qH := Image( q );;

gap> K := IsomorphismGroups( pG, qH );
[ f1, f2, f3 ] -> [ f2, f1*f2, f1*f2*f3 ]

Of course, if you have one isomorphism, you can calculate the automorphism group of either the source or range group, and compose with the previously mentioned isomorphism.

As for your questions:

1. Since you didn't provide any example code, I'm not sure what went wrong, but both things you mentioned should work. They are mentioned under 32.4-6 Image.

gap> pg := Random( pG );
f2
gap> K(pg);
f1*f2
gap> pg^K;
f1*f2

You could also use the other commands mentioned in the same section of the GAP manual:

gap> ImagesRepresentative( K, pg );
f1*f2
gap> ImageElm( K, pg );
f1*f2
gap> Image( K, pg );
f1*f2

2. In thise case, you will want to use PreImagesRepresentative (32.5-4).

gap> qh := pg^K;
f1*f2
gap> h := PreImagesRepresentative( q, qh );
x*y
gap> h in H;
true