$K_{11}$ covered by pentagons such that...

Question

Can the complete graph on $11$ vertices, $K_{11}$, be covered by pentagons, such that each pair of pentagons shares exactly two points (and no edges.)

If we drop the restriction that each pair shares exactly 2 points, it can be done. Take the pentagon $\{1,2,5,9,7 \}$ and generate the rest by adding $1$ to each value, and so on, taking the values mod $11$.

Answer 1

Mathematica's clique-finding algorithm says that one such set of pentagons is $$(1,2,3,4,5) \quad (1,3,6,7,8) \quad (1,7,10,2,9) \quad (1,4,8,9,11) \\ (1,6,11,5,10) \quad (2,6,9,3,11) \quad (2,4,10,6,8) \quad (2,5,8,11,7) \\ (3,7,4,11,10) \quad (3,5,9,10,8) \quad (4,6,5,7,9).$$

So that this answer has some content to it, here's my Mathematica code.

subsets = Subsets[Range[11], {5}];
pents[s_] := Select[Permutations[s], #[[1]] == Min[#] && #[[2]] < #[[5]] &]
pentagons = Flatten[pents /@ subsets, 1];
adjacentQ[p1_, p2_] := 
  Length@Intersection[p1, p2] == 2 && 
  Length@Intersection[Sort /@ Partition[p1, 2, 1, 1], Sort /@ Partition[p2, 2, 1, 1]] == 0

first = {1, 2, 3, 4, 5};
second = {1, 3, 6, 7, 8};

rest = Select[pentagons, adjacentQ[#, first] && adjacentQ[#, second] &];
edges = #[[1]] <-> #[[2]] & /@ Select[Subsets[rest, {2}], adjacentQ @@ # &];
graph = Graph[rest, edges];

FindClique[graph]

It computes all the pentagons, and defines adjacentQ to be the relation that says when two pentagons share two vertices but no edges. To symmetry-break a little, we choose $(1,2,3,4,5)$ and $(1,3,6,7,8)$ to be the first two pentagons, limiting our search to pentagons compatible with both of these. Then we build the graph in which two pentagons are adjacent when adjacentQ is true of them, and find a clique in this graph.