linear algebra 1, linear applications

Question

Given the endomorphism f defined by its associated matrix A, A=((a,-3),(-2,-2)) relative to the canonical base R^2. Find the variable a so that f admets a line of fixed points.

Solution is a=7, line is centered at the origin and is directed by the vector (1,2).

---

Normally, if a was given I could solve this problem- A*x=x - but as there are two variables I don't know how to go about finding a.

Answer 1

Try Eigenvalues and look for a such that eigenvalue ==1

ev = Eigenvalues[{{a, -3}, {-2, 2}} ]
(*{1/2 (2 + a - Sqrt[28 - 4 a + a^2]),1/2 (2 + a + Sqrt[28 - 4 a + a^2])}*)

Solve[ev[[1]] == 1, a] (*{a->7}*)
Solve[ev[[2]] == 1, a] (*{}*)

Only the first eigenvector corresponding to a=7

Eigenvectors[{{a, -3}, {-2, 2}} ][[1]]/.a->7 
(* {1/2,1}*) 

defines the line of fixpoints

ParametricPlot[ {1/2,1} t,{t,-1,1}]

Answer 2

We are looking for a line, consisting of points (vectors):v that are invariant under multiplication with m: v== m.v. Vectors that are mapped into a mutliple (called Eigenvalue): mul of themself by m are called eigenvectors: m.vec== mul vec. In our case, mul must be: mul ==1. Therefore we are looking for an eigenvector with eigenvalue 1.

Eigenvalues can be calulated by: Det[m- eigenvalue IdentitytMatrix]==0, or with the built in function Eigenvalues. We then determine a so that the eigenvalues is: 1

m = {{a, -3}, {-2, 2}};
ev1 = Solve[Eigenvalues[m][[1]] == 1, a][[1]]
(*  {a -> 7} *)

Setting this value for a in m, we calculate the belonging eigenvectors by:

m = m /. ev1
Eigenvectors[m]
(* {{-3, 1}, {1, 2}}  *)

We see that there are 2 invariant lines, namely: {x,y}== lam {-3,1} and {x,y}== lam {1,2}

Answer 3

The problem as described quite nicely in the OP, ignoring linear algebra, seems a job for SolveAlways. But we can't completely ignore algebra and need to exclude the singularity at $x=0$ before $x$ can be eliminated by the software without eliminating everything.

amat = {{a, -3}, {-2, 2}};
x = {x1, x2};

Solve[{amat . x == x, x != 0}, a, x]
(*  {{a -> 7}}  *)

Besides, if this is a homework problem, the intention of Mathematica is to take all the drudgery out of having deal with such boring and complicated topics as eigenvectors. In due fairness to the problem, it's a simple Algebra I/II problem in which the elimination of, say, x2 from the system {a x1 - 3 x2 == x1, -2 x1 + 2 x2 == x2} can practically be done in one's head. Or for those who shy away from such drudgery (adjust the commented code to suit your personal level of abhorrence):

Eliminate[{a x1 - 3 x2 == x1, -2 x1 + 2 x2 == x2}, {x2}] (* // Solve *)
(*  a x1 == 7 x1  *)