Manipulating ideal generators

Question

Given the field $K = \mathbb{Q}(\vartheta)$ with $\vartheta = \sqrt{-73}$, I'm trying to determine the structure of the class group $\mathrm{Cl}(K)$. By using the Minkowski Theorem and Kummer-Dedekind Theorem, I determined that $\mathrm{Cl}(K)$ is generated by the ideal classes of the ideals $$ \mathfrak{p}_{2} = \langle 2, \vartheta - 1 \rangle, \hspace{20pt} \mathfrak{p}_{71} = \langle 7, \vartheta - 2 \rangle, \hspace{20pt} \mathfrak{p}_{72} = \langle 7, \vartheta + 2 \rangle, $$ where $$ \mathfrak{p}_{2}^{2} = \langle 2 \rangle, \hspace{20pt} \mathfrak{p}_{71}\mathfrak{p}_{72} = \langle 7 \rangle. $$ Thus, by writing $[\mathfrak{p}_{i}]$ for the ideal class of the ideal $\mathfrak{p}_{i}$, we have $$ [\mathfrak{p}_{2}]^{2} = [1] \hspace{20pt}\text{and}\hspace{20pt} [\mathfrak{p}_{71}][\mathfrak{p}_{2}] = [1] $$ so that $$ [\mathfrak{p}_{2}] = [\mathfrak{p}_{2}]^{-1} \hspace{20pt}\text{and}\hspace{20pt} [\mathfrak{p}_{71}] = [\mathfrak{p}_{2}]^{-1}. $$ I'm trying to determine the order of and relationship between the ideal classes. For example, I tried to determine the product $[\mathfrak{p}_{2}][\mathfrak{p}_{71}]$ by finding the product $\mathfrak{p}_{2}\mathfrak{p}_{71}$. This is where I encounter an issue.

By expressing the ideals as their generators, we have $$ \mathfrak{p}_{2}\mathfrak{p}_{71} = \langle 2, \vartheta - 1 \rangle\langle 7, \vartheta - 2 \rangle = \langle 14, 2\vartheta - 4, 7\vartheta - 7, -71 + 3\vartheta \rangle $$ since $\vartheta^{2} = -73$. Then $$ \begin{array}{c} (-71 + 3\vartheta) + 5(14) = -1 + 3\vartheta \in \mathfrak{p}_{2}\mathfrak{p}_{71},\\ (-7 + 7\vartheta) - 3(2\vartheta - 4) = 5 + \vartheta \in \mathfrak{p}_{2}\mathfrak{p}_{71},\\ (-4 + 2\vartheta) - 5(-1 + 3\vartheta) = 1 - 13\vartheta \in \mathfrak{p}_{2}\mathfrak{p}_{71},\\ 13(5 + \vartheta) + (1 - 13\vartheta) = 66 \in \mathfrak{p}_{2}\mathfrak{p}_{71}.\\ \end{array} $$ Now $66 - 4(14) = 10 \in \mathfrak{p}_{2}\mathfrak{p}_{71}$, and then $14 - 10 = 4 \in \mathfrak{p}_{2}\mathfrak{p}_{71}$, so that $14 - 2(4) = 2 \in \mathfrak{p}_{2}\mathfrak{p}_{71}$.

Now that $2 \in \mathfrak{p}_{2}\mathfrak{p}_{71}$, we can observe that $$ (5 + \vartheta) - 3(2) = \vartheta - 1 \in \mathfrak{p}_{2}\mathfrak{p}_{71}, $$ and then each of the generators $$ 14, 2\vartheta - 4, 7\vartheta - 7, -71 + 3\vartheta $$ are $\mathbb{Z}[\vartheta]$-linear combinations of $2$ and $\vartheta - 1$, so $$ \mathfrak{p}_{2}\mathfrak{p}_{71} = \langle 2, \vartheta - 1 \rangle\langle 7, \vartheta - 2 \rangle = \langle 14, 2\vartheta - 4, 7\vartheta - 7, -71 + 3\vartheta \rangle = \langle 2, \vartheta - 1 \rangle = \mathfrak{p}_{2} $$ and thus $$ \mathfrak{p}_{2}\mathfrak{p}_{71} = \mathfrak{p}_{2}. $$ This does not feel right at all. Have I just made a silly mistake somewhere, or is there something going on that I'm unaware of?

Answer 1

Let us use sage to make the computations. First of all, let us have a clear picture of the class group of the given field. Code:

K.<t> = QuadraticField( -73 )
G = K.class_group()
print "K = %s" % K
print "G = Cl(K) is %s" % G
print "G has %s generator(s)" % len(G.gens())

Results:

K = Number Field in t with defining polynomial x^2 + 73
G = Cl(K) is Class group of order 4 with structure C4 of Number Field in t with defining polynomial x^2 + 73
G has 1 generator(s)

Sage uses the generator:

sage: G.gens()
(Fractional ideal class (7, t + 5),)

Now back to the post.

sage: p2  = K.ideal( 2, t-1 )
....: p71 = K.ideal( 7, t-2 )
....: p72 = K.ideal( 7, t+2 )
....: 
sage: p2*p2
Fractional ideal (2)
sage: p71*p72
Fractional ideal (7)
sage: p71*p2
Fractional ideal (14, t + 5)
sage: p72*p2
Fractional ideal (14, t + 9)

So the class of $\mathfrak p_2\cdot \mathfrak p_{72}$ is not trivial.

The error was in the first line of the computation, note that

sage: (t-1)*(t-2)
-3*t - 71

so there is a minus three as coefficient. The difference is:

sage: q = K.ideal( 14, 2*t-4, 7*t-7, -71+3*t )    # false +3 coeff
sage: q
Fractional ideal (2, t + 1)
sage: q == p2*p71
False
sage: q == p2
True
sage: K.ideal( 14, 2*t-4, 7*t-7, -71-3*t )    # coeff -3 is ok
Fractional ideal (14, t + 5)
sage: p2*p71 == _
True

(The underscore stays for the "last result so far".)