Permutation calculator

Question

I am studying the Mathieu group $M_{11}$ on the twelve letters $\infty,7,6,8,X,2,0,3,4,1,9,5$ (in this specific order) in the form that it is generated by the permutations $(0123456789X)$, $(13954)(267X8)$ and $(\infty 0)(18)(7364)(29X5)$ (as in Wilson, "The Complex Leech Lattice and Maximal Subgroups of the Suzuki Group").

Now I need to find two elements of $M_{11}$:

One element should take $8$ to $\infty$ while fixing the coordinates $7$ and $6$ as a whole (i.e. possibly interchanging them).

Another element should take $2$ to $\infty$ while fixing the coordinates $0$ and $1$ as a whole (i.e. possibly interchanging them).

Is there some way or a program which can be used for computing such permutations?

Answer 1

It seems to me that there is a typo in the formulation of the question because the paper "The Complex Leech Lattice and Maximal Subgroups of the Suzuki Group" by R.Wilson gives $(0123456789X)$, $(13954)(267X8)$ and $(\infty 0)(18)(7364)(29X5)$ as generators for $M_{11}$ on page 153 (note also that $X$ and $8$ are in the reverse order in the question).

Anyhow, the question is "Is there some way or a program which can be used for computing such permutations?" and I will demonstrate that this is doable with GAP.

First I want to automate a little bit conversion from $\infty,7,6,8,X,2,0,3,4,1,9,5$ (in this specific order) to permutations acting on [1..12]:

This is a list of letters on which the group is acting:

gap> l:=[infinity,7,6,8,'X',2,0,3,4,1,9,5];
[ infinity, 7, 6, 8, 'X', 2, 0, 3, 4, 1, 9, 5 ]

This is a list of letters in the cycle notation for the 1st permutation $(0123456789X)$:

gap> s:=[0,1,2,3,4,5,6,7,8,9,'X'];
[ 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 'X' ]

Now their positions in the list l:

gap> List(s,i->Position(l,i));
[ 7, 10, 6, 8, 9, 12, 3, 2, 4, 11, 5 ]

I am not really happy about the next step, because I am just copying and pasting the last output replacing [ ] by ( ) but one should be able to automate this too:

gap> u:=(7, 10, 6, 8, 9, 12, 3, 2, 4, 11, 5);
(2,4,11,5,7,10,6,8,9,12,3)

So, this is the 1st generator translated to an element of the permutation group acting on 12 points that we are going to construct.

Similarly, we have for $(13954)(267X8)$

gap> s:=[1,3,9,5,4,2,6,7,'X',8];
[ 1, 3, 9, 5, 4, 2, 6, 7, 'X', 8 ]
gap> List(s,i->Position(l,i));
[ 10, 8, 11, 12, 9, 6, 3, 2, 5, 4 ]
gap> v:=(10, 8, 11, 12, 9)(6, 3, 2, 5, 4);
(2,5,4,6,3)(8,11,12,9,10)

(also inserting extra parentheses for the cycle structure), and for $(\infty 0)(18)(7364)(29X5)$

gap> s:=[infinity,0,1,8,7,3,6,4,2,9,'X',5];
[ infinity, 0, 1, 8, 7, 3, 6, 4, 2, 9, 'X', 5 ]
gap> List(s,i->Position(l,i));
[ 1, 7, 10, 4, 2, 8, 3, 9, 6, 11, 5, 12 ]
gap> w:=(1, 7)(10, 4)(2, 8, 3, 9)(6, 11, 5, 12);
(1,7)(2,8,3,9)(4,10)(5,12,6,11)

Now we will construct the group acting on 12 points and check that this is $M_{11}$:

gap> M:=Group(u,v,w);
Group([ (2,4,11,5,7,10,6,8,9,12,3), (2,5,4,6,3)(8,11,12,9,10), 
        (1,7)(2,8,3,9)(4,10)(5,12,6,11) ])
gap> Size(M);
7920
gap> IsSimple(M);
true
gap> StructureDescription(M);
"M11"

Next, we will find an element of $M$ which swaps $8$ and $\infty$ while fixing the letters $7$ and $6$. We will use RepresentativeAction specifying that M acts on tuples, and give two tuples of positions of these letters in the list l:

gap> RepresentativeAction(M,[4,1,2,3],[1,4,2,3],OnTuples);
(1,4)(5,6)(8,11)(9,12)

Translating it back to letters, we have the permutation $(\infty,8)(X,2),(3,9)(4,5)$

Similarly, to find an element that should take $2$ to $\infty$ while fixing the coordinates $0$ and $1$, we obtain:

gap> RepresentativeAction(M,[6,1,7,10],[1,6,7,10],OnTuples);
(1,6)(2,9)(4,8)(5,11)

which corresponds to $(\infty,2)(7,4)(8,3)(X,9)$.

---

Update: As noted by @ahulpke, one could also just replace $\infty$, $0$ and $X$ by other numbers and leave all other numbers intact. This will make the translation to the notation from the paper easier. Indeed, let's use 50 for $0$, $66$ for $X$ and 88 for $\infty$. Then we have

gap> u:= ( 50, 1, 2, 3, 4, 5, 6, 7, 8, 9, 66 );
(1,2,3,4,5,6,7,8,9,66,50)
gap> v:=(1,3,9,5,4)(2,6,7,66,8);
(1,3,9,5,4)(2,6,7,66,8)
gap> w:=(88,50)(1,8)(7,3,6,4)(2,9,66,5);
(1,8)(2,9,66,5)(3,6,4,7)(50,88)
gap> G:=Group(u,v,w);
<permutation group with 3 generators>
gap> Size(G);
7920
gap> StructureDescription(G);
"M11"

and may then continue in the same way.