Quotient of elliptic riemann surface by $\mathbb{Z}/3$

Question

Consider an elliptic curve $E$ and a non-zero point $a\in E$ of order three. Translation by $a$ is an automorphism $\tau_a:E\to E, x\mapsto x+a$ of order $3$ of the Riemann surface $E$. Could you please give me an idea how to get an equation of $E/G$ if an equation of $E$ is given? In my case $E$ is given by $y^2 = x^4 + 10x^3 +25x^2 -100x.$

Any help would be appreciated!

Answer 1

Yes, this can be done using Vélu's formulae; see here for a translation of his article Isogénies entre courbes elliptiques. These formulae have been implemented in Magma. Below is code for computing the equation.

First we put the curve into standard Weierstrass form with a cubic:

QQ := Rationals();
R<x,y> := PolynomialRing(QQ,2);
f := y^2 - (x^4 + 10*x^3 + 25*x^2 - 100*x);
C0 := Curve(Spec(R),f);
C := ProjectiveClosure(C0);
E0, mp0 := EllipticCurve(C, C![0,0,1]);
E, mp := MinimalModel(E0);

This gives the curve $E: y^2 + xy + y = x^3 - 76 x + 298$. Computing the torsion subgroup of $E$ with

T, mpT := TorsionSubgroup(E);

we find that the $3$-torsion of $E$ over $\mathbb{Q}$ consists of the points $$ (0 : 1 : 0), \quad (2 : 11 : 1), \quad (2 : -14 : 1) \, . $$ We then use the command IsogenyFromKernel to compute the isogeny, which takes as input a polynomial cutting out the $x$-coordinates of the points in our subgroup:

S<t> := PolynomialRing(QQ);
E2, mp2 := IsogenyFromKernel(E,t-2);

This returns the elliptic curve $$ E_2 : y^2 + xy + y = x^3 + 549x - 2202 \, . $$ We can verify that $E_2$ is $3$-isogenous to our original curve:

> IsIsogenous(E,E2);
true Elliptic curve isogeny from: CrvEll: E to CrvEll: E2
taking (x : y : 1) to ((x^3 - 4*x^2 - 121*x + 875) / (x^2 - 4*x + 4) : (x^3*y - 6*x^2*y + 125*x^2 + 137*x*y - 1250*x - 1508*y + 125) / (x^3 - 6*x^2 + 12*x - 8) : 1)
> _, phi := $1;
> Degree(phi);
3