semidirect product between subgroup of general linear group and vector space in GAP

Question

I am currently working on trying to get a solvable doubly transitive permutation group using GAP. So, I am trying to create the semidirect product of a subgroup of a general linear group and a vector space. Currently I am trying to work with the group GL(2,3) and vector space V of dimension 2 over the field of 3 elements. I don't know if this is possible, since it seems like both parts of the semidirect product needs to be a group and I need a homomorphism from GL to V. I am new to GAP so I don't know what I can do to achieve this.

Answer 1

For the special case of a semidirect product of a matrix group with its natural vector space you can use SemidirectProduct without homomorphism:

gap> matgrp:=GL(2,3);
GL(2,3)
gap> sdp:=SemidirectProduct(matgrp,GF(3)^2);
<matrix group of size 432 with 3 generators>

The result is the semidirect product as an affine matrix group, that is the upper left corner is the matrix part and the last row (except from the last entry $1$) is the vector space part.

To get the permutation action on 9 points, you need to get the conjugation action (OnPoints) of the matrix part, together with the translation action (multiplication, OnRight) of the vector space part:

gap> normal:=Image(Embedding(sdp,2));;
gap> Size(normal);
9
gap> normalelms:=Elements(normal);;
gap> matrixpart:=Image(Embedding(sdp,1));;
gap> act1:=Action(matrixpart,normalelms,OnPoints);
Group([ (4,7)(5,8)(6,9), (2,7,6)(3,4,8) ])
gap> act2:=Action(normal,normalelms,OnRight);
Group([ (1,4,7)(2,5,8)(3,6,9), (1,2,3)(4,5,6)(7,8,9) ])

Together this gets the 2-transitive permutation action

gap> permrep:=ClosureGroup(act1,act2);
Group([ (4,7)(5,8)(6,9), (2,7,6)(3,4,8), (1,4,7)(2,5,8)(3,6,9) ])
gap> Size(permrep);
432
gap> Transitivity(permrep);
2