Solving system of algebraic equations with Maple

Question

Solutions are as follows:

How can I find these solutions for the above system of algebraic equations with Maple for $a_0, a_1, \alpha_0, \alpha_1, b_1, \beta_1.$

Answer 1

It is inconsiderate of you to to post only an image of your equations. I typed them into Maple 2019.2,

eqs:=[
  2*p*a[1]*alpha[1]*lambda-2*a[1]*lambda^2+2*a[1]^2*lambda,
  c*a[1]*lambda+p*a[0]*alpha[1]*lambda+p*a[1]*alpha[0]*lambda
    +2*a[0]*a[1]*lambda,
  2*p*a[1]*alpha[1]*mu-2*a[1]*lambda*mu+2*a[1]^2*mu,
    -c*b[1]*lambda-2*a[0]*b[1]*lambda+p*a[1]*alpha[0]*mu
  +p*a[0]*alpha[1]*mu+c*a[1]*mu+2*a[0]*a[1]*mu
    -p*b[1]*alpha[0]*lambda-p*a[0]*beta[1]*lambda,
  -2*p*b[1]*beta[1]*lambda-2*b[1]^2*lambda-2*b[1]*mu*lambda,
  -p*a[0]*beta[1]*mu-c*b[1]*mu-2*a[0]*b[1]*mu
    -p*b[1]*alpha[0]*mu,
  -2*p*b[1]*beta[1]*mu-2*b[1]^2*mu-2*b[1]*mu^2,
  2*q*a[1]*alpha[1]*lambda-2*alpha[1]*lambda^2
    +2*alpha[1]^2*lambda,
  c*alpha[1]*lambda+2*alpha[0]*alpha[1]*lambda
    +q*a[0]*alpha[1]*lambda+q*a[1]*alpha[0]*lambda,
  -2*alpha[1]*lambda*mu+2*alpha[1]^2*mu+2*q*a[1]*alpha[1]*mu,
  q*a[1]*alpha[0]*mu-c*beta[1]*lambda+q*a[0]*alpha[1]*mu
    +2*alpha[0]*alpha[1]*mu-q*a[0]*beta[1]*lambda
    -q*b[1]*alpha[0]*lambda+c*alpha[1]*mu
    -2*alpha[0]*beta[1]*lambda,
  -2*beta[1]*mu*lambda-2*beta[1]^2*lambda
    -2*q*b[1]*beta[1]*lambda,
  -q*b[1]*alpha[0]*mu-q*a[0]*beta[1]*mu-c*beta[1]*mu
    -2*alpha[0]*beta[1]*mu,
  -2*beta[1]^2*mu-2*q*b[1]*beta[1]*mu-2*beta[1]*mu^2
]:

Your desired solutions all contain alpha[0]=alpha[0], ie. that it is arbitrary. The following call to the solve command implies that the remaining indeterminate names (parameters) are free. If I wanted to consider cases where the solutions were constrained by relationships amongst remaining parameters then I could utilize another command, eg. eliminate.

S := solve(eqs,[a[0],a[1],b[1],alpha[1],beta[1],c]):

The following includes a few special cases, in addition to the three you described. (The order in which they appear in solution S may vary.)

map(lprint,S):

  [a[0]=alpha[0]*(p-1)/(q-1), a[1]=0, b[1]=-(p-1)*mu/(p*q-1),
   alpha[1]=0, beta[1]=-mu*(q-1)/(p*q-1),
   c=-2*alpha[0]*(p*q-1)/(q-1)]

  [a[0]=alpha[0]*(p-1)/(q-1), a[1]=(p-1)*lambda/(p*q-1),
   b[1]=0, alpha[1]=lambda*(q-1)/(p*q-1), beta[1]=0,
   c=-2*alpha[0]*(p*q-1)/(q-1)]

  [a[0]=alpha[0]*(p-1)/(q-1), a[1]=(p-1)*lambda/(p*q-1),
   b[1]=-(p-1)*mu/(p*q-1), alpha[1]=lambda*(q-1)/(p*q-1),
   beta[1]=-mu*(q-1)/(p*q-1), c=-2*alpha[0]*(p*q-1)/(q-1)]

  [a[0]=a[0], a[1]=0, b[1]=0, alpha[1]=0, beta[1]=0, c=c]

  [a[0]=0, a[1]=0, b[1]=0, alpha[1]=0, beta[1]=-mu,
   c=-2*alpha[0]]

  [a[0]=0, a[1]=0, b[1]=0, alpha[1]=lambda, beta[1]=-mu,
   c=-2*alpha[0]]

  [a[0]=0, a[1]=0, b[1]=0, alpha[1]=lambda, beta[1]=0,
   c=-2*alpha[0]]