some particular extensions of $SL_2(5)$

Question

With GAP software, I can calculate \begin{gather}\dim H^2(SL(2,5),GF(2)^9)=1 \end{gather} So, if I understand correctly, there is exactly one non-split extension of $SL(2,5)$ by an elementary abelian $2$-group of dimension $2^9$. Let's say I want to know the character table of this extension. Then I look for all perfect groups $K$ of size $120\cdot2^9$. Unfortunately, GAP seems that doen't help me.

gap> NrPerfectGroups(120*2^9); 
fail

The GAP's library PerfectGroup relies on the book "Perfect Groups" of Holt and Plesken, but I didn't find information neither there.

Edit: I was trying to get the information about a perfect group $K$ with the following properties: there is $M \unlhd K$ an elementary abelian group of order $2^9$ such that $M=C_K(M)$, $K/M$ si isomorphic to $SL(2,5)$ and acts irreducibly on $M$. Hence what I calculated with GAP is the cohomology group $H^2(SL(2,5),M)$ where $M$ is an irreducible faithful $SL(2,5)$ module.

Answer 1

Since $SL(2,5)$ is the Schur covering of $A_5$, its irreducible modules are known (they can be foun with GAP or here, note that also the indecomposable representations are listed, so be careful on what you're reading). More generaly, $O_2(SL(2,5))=Z(SL(2,5))$ has order $2$, hence it acts trivially on every irreducible representations in characteristic $2$. Equivalently, the irreducible representations of $SL(2,5)$ in even characteristic are the same of $A_5$ and cant be faithful. For further details, see the helpful comments of Jack and Derek.

Answer 2

If we take the 9-dimensional indecomposable module listed on the ATLAS webpages (as indicated in a commentary), we can construct the corresponding nonsplit extension in GAP as follows:

gap> LoadPackage("atlasrep");;
gap> DisplayAtlasInfo("2.A5");
Representations for G = 2.A5:    (all refer to std. generators 1)
-----------------------------
 1: G <= Sym(24)                             rank 8, on cosets of 5 < 2.D10
 2: G <= Sym(40)                             rank 16, on cosets of 3 < 2.S3
 3: G <= GL(8,2)
 4: G <= GL(9,2)
[...] Rest deleted

so we want representation 1 for permutations and representation 4 for the module:

gap> perms:=AtlasGenerators("2.A5",1).generators;
[ (1,2,5,4)(3,6,8,7)(9,13,11,14)(10,15,12,16)(17,19,18,20)(21,24,23,22),
  (1,3,2)(4,5,8)(6,9,10)(7,11,12)(13,16,17)(14,15,18)(19,21,22)(20,23,24) ]
gap> mats:=AtlasGenerators("2.A5",4).generators;
[ <an immutable 9x9 matrix over GF2>, <an immutable 9x9 matrix over GF2> ]
gap> gp:=Group(perms);;
gap> mo:=GModuleByMats(mats,GF(2));;
gap> coh:=TwoCohomologyGeneric(gp,mo);;
gap> coh.cohomology; # indeed dimension 1
[ <an immutable GF2 vector of length 144> ]

Now form the extension:

gap> gp:=FpGroupCocycle(coh,coh.cohomology[1]);
<fp group of size 61440 on the generators [ F1, F2, F3, F4, m1, m2, m3, m4,  m5, m6, m7, m8, m9 ]>
gap> gp:=Image(IsomorphismPermGroup(gp));
<permutation group of size 61440 with 13 generators>

Should you like the full library of perfect groups that I computed (which will be in the future GAP 4.12 release) send me a private email and I'm happy to provide you with a link.