Writing a series of polynomial equations of certain degree from a sequence of binary bits using Magma

Question

How do I write a series of polynomial equations of a specified degree from a sequence of binary bits using Magma. So far, I have the following code for converting a decimal sequence to binary.

for i in [0..255]
do
Intseq(i,2); 
end for;

How do I add increasing powers of $x$ such that: if "desired degree $=7$"then the binary sequence $$[ 1, 0, 1, 1 ]$$ which represents 11 will be written as "$x^3+x+1$" and $$[ 1, 0, 0, 1, 1, 1 ]$$ will be written as "$x^5+x^2+x+1$".

Answer 1

I don't see where the "desired degree" comes into your question. Leaving that aside, there is further the issue of what coefficient ring you are intending to use -- it seems like $\mathbb{F}_2$ would be most appropriate, but maybe you mean $\mathbb{Z}$. For now I'll assume that you are working over $\mathbb{Z}$.

The first step is to create the corresponding polynomial ring (and, usually, to also name the variable). A polynomial can then be created by using the coercion operator '!'. A minor caveat, however: In MAGMA, it is usual to put the smaller degrees first. This means that the sequences would be reversed from your representation above. If you are iterating through all bit patterns then this should not concern you, but if it does then remember to use Reverse() on the sequence first.

Example:

> Zx<x> := PolynomialRing(Integers());
> Zx![1, 1, 1, 0, 0, 1];
x^5 + x^2 + x + 1
> Zx!Reverse([1, 0, 0, 1, 1, 1]);
x^5 + x^2 + x + 1

If, instead, you wanted your polynomials to be defined over $\mathbb{F}_2$, then all you would need to adjust is the polynomial ring:

> P<t> := PolynomialRing(GF(2));
> P![1, 1, 1, 0, 0, 1];
t^5 + t^2 + t + 1

Putting this together with your original idea, you could (for instance) generate all polynomials over $\mathbb{F}_2$ with degree at most 7 by doing the following:

> P<t> := PolynomialRing(GF(2));
> for i in [0..2^8 - 1] do
>     f := P!Intseq(i, 2);
>     // do something with f
> end for;

Or if you just wanted a sequence of such polynomials:

> P<t> := PolynomialRing(GF(2));
> S := [ P!Intseq(i, 2) : i in [0..2^8 - 1] ];