A question about an exercise in Marcus book “Number Fields”

Question

The exercise is the number 27 in chapter 3. “Let $\alpha^5=5(\alpha+1), K=\mathbb{Q}(\alpha)$ and let $p\neq3$ a prime of $\mathbb{Z}.$ Show that the prime decomposition of $p\mathcal{O}_K$ can be determined by factoring $x^5-5x-5 \mod{p}.$

I know Kummer theorem. A simple calculation shows that $disc(\alpha)=5^5\cdot3^2\cdot41.$ Since $disc(\alpha)=ind(\alpha)^2\cdot disc(K),$ clearly $41\nmid ind(\alpha).$ So the only prime that can create some problems is $5.$ How can I prove that $5\nmid ind(\alpha)?$

Answer 1

First of all, let us have the "final picture", asking a computer algebra system, sage in my case, to give us the full relevant data.

I will use $a$ instead of $\alpha$.

sage: R.<x> = PolynomialRing(QQ)
sage: K.<a> = NumberField( x^5 - 5*(x+1) )
sage: K
Number Field in a with defining polynomial x^5 - 5*x - 5
sage: a.minpoly()
x^5 - 5*x - 5
sage: a.trace(), a.norm()    # fishing coefficients above
(0, 5)

sage: Oa = K.order(a)
sage: Oa
Order in Number Field in a with defining polynomial x^5 - 5*x - 5
sage: Oa.basis()
[1, a, a^2, a^3, a^4]
sage: Oa.discriminant().factor()
3^2 * 5^5 * 41

sage: OK = K.OK()
sage: OK
Maximal Order in Number Field in a with defining polynomial x^5 - 5*x - 5
sage: OK.basis()
[2/3*a^4 + 2/3*a^3 + 2/3*a^2 + 2/3*a + 1/3, a, a^2, a^3, a^4]
sage: OK.discriminant().factor()
5^5 * 41
sage: K.discriminant().factor()
5^5 * 41

sage: ZZ( Oa.discriminant() / OK.discriminant() ).factor()
3^2
sage: Oa.index_in(OK)
3

Sage has a mathematically oriented thinking, and the names of the objects and methods reflect the mathematical names for them, so the above is pretty readable also without sage and/or python knowledge. Now let us show "manually" that there is no factor $5$ in the index of $a$.

For this, let us use as a parallel the receipt in John Paul Cook, Computing Integral Bases. The prime $5$ is "in" the index, iff we find an integral number in $K$ of the shape $$ S = \frac 15\Big(\ s_0+s_1a+s_2a^2+s_3a^3+s_4a^4\ \Big)\in \Bbb Q(a), \ s_0,s_1,s_2,s_3,s_4\in\{0,1,2,3,4\}\ , $$ which is not in $\Bbb Z[a]$.

We will not follow his general plan, since

• Step (4): Compute the trace of $S$. Using sage again:

  sage: [ (a^k).trace() for k in [0..4] ]
  [5, 0, 0, 0, 20]
  

  so the traces of $1,a,a^2,a^3,a^4$ are all divisible by $5$, so we get no supplementary information.

• Step (5): We could compute the norm of $S$, sage again:

  sage: A = a.complex_embeddings()
  sage: A
  [-1.04715267329829 - 0.305073598291014*I,
   -1.04715267329829 + 0.305073598291014*I,
   0.206905667673302 - 1.56789630940964*I,
   0.206905667673302 + 1.56789630940964*I,
   1.68049401124998]
  

  and then numerically,

  s = var( 's0 s1 s2 s3 s4' )
  P = prod( [ sum( [ s[j]*A[k]^j for j in [0..4]] ) for k in [0..4] ] ).expand().polynomial(CC)
  

  then round the coefficients. But again, we get too many monomials.

We could try to refine, and simplify the situation, e.g. passing from $s_0\to 5-s_0$, if $s_0\ne 0$, (and also changing the further coefficients), but it will still remain a mess. No problem with the computer:

sage: J = [0,1,2,3,4]
sage: for s0,s1,s2,s3,s4 in cartesian_product( [J,J,J,J,J] ):
....:     b = (s0 + s1*a + s2*a^2 + s3*a^3 + s4*a^4)/5
....:     if b.norm() in ZZ:
....:         print b
....:         
0

So it finds only the zero. In contrast, The same code, using the denominator $3$ is finding...

sage: J = [0,1,2]
sage: for s0,s1,s2,s3,s4 in cartesian_product( [J,J,J,J,J] ):
....:     b = (s0 + s1*a + s2*a^2 + s3*a^3 + s4*a^4)/3
....:     if b.norm() in ZZ:
....:         print b
....: 
0
2/3*a^4 + 2/3*a^3 + 2/3*a^2 + 2/3*a + 1/3
2/3*a^4 + 1/3*a^2 + 1/3*a + 2/3
1/3*a^4 + 1/3*a^3 + 1/3*a^2 + 1/3*a + 2/3

---

The human solution for the problem, replacing the exhaustive search, could be as follows.

Start with an integral $$ S = \frac 15\Big(\ s_0+s_1a+s_2a^2+s_3a^3+s_4a^4\ \Big)\in \Bbb Q(a), \ s_0,s_1,s_2,s_3,s_4\in\{0,1,2,3,4\}\ . $$ Then $aS$ is also integral. The coefficients are "shifted", and we get the integral element $$ aS = \frac 15\Big(\ s_0a+s_1a^2+s_2a^3+s_3a^4+s_4\underbrace{a^5}_{\frac 15(a+1)}\ \Big)\ . $$ With further shiftings, we get a list of "derived" integral numbers: $$ \begin{aligned} S &= \frac 15\Big(\ s_0+s_1a+s_2a^2+s_3a^3+s_4a^4\ \Big)\ ,\\ aS &= \frac 15\Big(\ s_0a+s_1a^2+s_2a^3+s_3a^4\ \Big)+\text{integral number}\ ,\\ a^2S &= \frac 15\Big(\ s_0a^2+s_1a^3+s_2a^4\ \Big)+\text{integral number}\ ,\\ a^3S &= \frac 15\Big(\ s_0a^3+s_1a^4\ \Big)+\text{integral number}\ ,\\ a^4S &= \frac 15\Big(\ s_0a^4\ \Big)+\text{integral number}\ . \end{aligned} $$ We compute the norms

sage: for k in [4,3,2,1,0]:
....:     print a^k/5, 'has norm', (a^k/5).norm().factor()
....:     
1/5*a^4 has norm 5^-1
1/5*a^3 has norm 5^-2
1/5*a^2 has norm 5^-3
1/5*a has norm 5^-4
1/5 has norm 5^-5

and see that successively we must have $s_0=0$, then $s_1=0$, then...

Answer 2

I looked for another approach to this problem as the accepted solution was a little too "bare hands" for my liking.

Letting $S = \mathbb{A} \cap K$ we have that $\alpha^5 = 5(\alpha+1)$; a previous exercise has you show that in $K$, $\alpha +1$ is a unit. Therefore $5S = (\alpha)^5$ and so 5 is totally ramified over $\mathbb{Q}$ ($e = 5, f = 1, r = 1$). Another exercise has you show that for any prime, $p^{k}$ divides the discriminant ($k = n - \sum f_i = n - 1$ here). Therefore for an integral basis of $K$, $5^4$ must divide $\text{disc}(S)$.

Coming back to the problem statement: $\text{disc}(\alpha) = (d_1 d_2 d_3 d_4)^2\text{disc}(S)$ where the $d_i$ are denominators of the integral basis. $d_1 d_2 d_3 d_4$ is also the order of $R[\alpha]$ in $S$. $\text{disc}(\alpha) = 5^5 \cdot 3^2 \cdot 41$ so the factor of $5^4$ must be in $\text{disc}(S)$, so $d_1 d_2 d_3 d_4 \in \{1, 3\}$. Therefore for any prime $p \neq 3$, $p \not\mid |S:R[\alpha]|$ and we can apply the Dedekind approach to determine its factorization in $S$.

Postscript: you can see with Sage that $d_1 d_2 d_3 d_4$ is actually $3$:

sage: K.<a> = QQ.extension(x^5 - 5*x - 5); K.integral_basis()
[2/3*a^4 + 2/3*a^3 + 2/3*a^2 + 2/3*a + 1/3, a, a^2, a^3, a^4]

Answer 3

The polynomial is Eisenstein for $p = 5$. Thus $5$ is completely ramified in the extension, and you're done.