A special subgroup of $S_{10}$ generated by four involutions

Question

Is there an easy way to describe the subgroup of $S_{10}$ generated by the four involutions: \begin{align*} & (4 ~ 7)(5 ~ 8)(6 ~ 9) \\ & (2 ~ 7)(3 ~ 8)(6 ~ 10) \\ & (1 ~ 7)(3 ~ 9)(5 ~ 10) \\ & (1 ~ 8)(2 ~ 9)(4 ~ 10) \end{align*} I mean is it isomorphic to some known group?

Answer 1

The group is isomorphic to $S_5$, the permutation representation is that on the cosets of the intransitive subgroup $S_2\times S_3$ with orbits of length 2 and 3.

This was done using GAP in the following way: Construct the group, verify that it is transitive on the 10 points moved, and identify it in the list (using a prior classification) of transitive groups of degree 10. (Probably http://oeis.org/A002106 is the easiest linked reference list for these classifications)

gap> g:=Group((4,7)(5,8)(6,9),(2,7)(3,8)(6,10),(1,7)(3,9)(5,10),
> (1,8)(2,9)(4,10));;
gap> IsTransitive(g,[1..10]);
true
gap> TransitiveIdentification(g);
13

If we fetch the associated group from the library we se that it is an action of $S_5$. (The names are explained in the paper by Conway, McKay and myself that is listed under the above link)

gap> TransitiveGroup(10,13);
S_5(10d)

Lets try to recreate this permutation group. It must be the action of $S_5$ on the cosets of a subgroup of order 12, find all these subgroups:

gap> h:=SymmetricGroup(5);                                                   
Sym( [ 1 .. 5 ] )
gap> u:=List(ConjugacyClassesSubgroups(h),Representative);;
gap> u:=Filtered(u,x->Size(x)=12);
[ Group([ (3,4,5), (2,4)(3,5) ]), Group([ (3,4,5), (4,5), (1,2)(4,5) ]) ]

Now look at the type of the action on the cosets of both subgroups. We find that it gives two different types and one of them is the ``correct'' subgroup for our purposes.

gap> List(u,x->TransitiveIdentification(Image(FactorCosetAction(h,x))));
[ 12, 13 ]
gap> v:=u[2];
Group([ (3,4,5), (4,5), (1,2)(4,5) ])
gap> Orbits(v,MovedPoints(h));
[ [ 1, 2 ], [ 3, 4, 5 ] ]

Since the subgroup has two orbits of length 2 and 3 it cannot be other than $S_2\times S_3$.