Action on Pairs, On Sets and on points in GAP

Question

I am trying to understand GAP in group action. I am confused in few things what is the difference between action on pairs, on sets, with the domain sometimes on list, and on blocks. Please help me to clarify these things. Thanks.

Answer 1

The "Group Actions" chapter of the GAP reference manual documents standard actions, and if you scroll until OnTuplesTuples, there will be a common example covering all of them. I will just take from there examples of the three actions in question, and try to shed more light.

First, create $A_4$ as g:

gap> g:=Group((1,2,3),(2,3,4));;
gap> AsList(g);
[ (), (2,3,4), (2,4,3), (1,2)(3,4), (1,2,3), (1,2,4), (1,3,2), (1,3,4), 
  (1,3)(2,4), (1,4,2), (1,4,3), (1,4)(2,3) ]

The group g acts transitively on the set $1,2,3,4$ so $1$ may be mapped to any of the points $1,2,3,4$:

gap> Orbit(g,1,OnPoints);
[ 1, 2, 3, 4 ]

For example:

gap> 1^(1,2)(3,4);
2
gap> 1^(1,3,2);
3
gap> 1^(1,4,2);
4

OnPairs extends OnPoints on pairs of points. A permutation s from g will map the pair [i,j] to [i^s,j^s]:

gap> Orbit(g,[1,2],OnPairs);
[ [ 1, 2 ], [ 2, 3 ], [ 1, 3 ], [ 3, 1 ], [ 3, 4 ], [ 2, 1 ], 
  [ 1, 4 ], [ 4, 1 ], [ 4, 2 ], [ 3, 2 ], [ 2, 4 ], [ 4, 3 ] ]

For example,

gap> OnPairs([1,2],(1,2,3));
[ 2, 3 ]
gap> OnPairs([1,2],(1,3,4));
[ 3, 2 ]

etc.

Finally, OnSets acts as OnPairs but additionally sorts the entries of the result:

gap> Orbit(g,[1,2],OnSets);
[ [ 1, 2 ], [ 2, 3 ], [ 1, 3 ], [ 3, 4 ], [ 1, 4 ], [ 2, 4 ] ]

Thus, [ 2, 3 ] and [ 3, 2 ] are not distinguished in the case of OnSets action:

gap> OnSets([1,2],(1,2,3));
[ 2, 3 ]
gap> OnSets([1,2],(1,3,4));
[ 2, 3 ]

Hope this helps to clarify things.