Are these two curves birationally equivalent?

Question

I'm trying to work out if the following two curves are birationally equivalent:

$$Y^2 = 2X^4 + 17X^2 + 12$$ $$2Y^2 = X^4 - 17$$

(I'm considering the above as the affine shorthands for the projective curves they represent)

I saw elsewhere online that I could use the following code in magma:

K<x,y>:=AffineSpace(Rationals(),2);
C1A:=Curve(K,2*x^4+17*x^2+12-y^2);
C2A:=Curve(K,x^4-17-2*y^2);
C1:=ProjectiveClosure(C1A);
C2:=ProjectiveClosure(C2A);
IsIsomorphic(C1,C2);

However this gives me a runtime error.

Can anyone see an error with my code/approach above? Alternatively, if there's another way I can check if two curves like the above are birationally equivalent either by hand or by using Magma / Sage or something similar that would be really helpful.

Answer 1

In PARI/GP:

? ellinit(ellfromeqn(2*x^4+17*x^2+12-y^2)).j
%1 = 384200066/111747
? ellinit(ellfromeqn(x^4-17-2*y^2)).j
%2 = 1728

The curves are not birationally equivalent because they have different $j$-invariants.

Answer 2

Smooth projective curves are birationally equivalent if and only if they are isomorphic (a rational map between smooth projective curves is automatically a morphism) - so we just want to find a smooth curve birationally equivalent to each $C_i$. The answer above is fine too, but I thought I'd continue your attempt at finding one with Magma.

I claim the curves are not birationally equivalent, so extending the field is fine (I will go to $L = \mathbb{Q}(\sqrt{-2}, \sqrt{31})$ ). I want to extend the base field simply to allow us to find some smooth points on $C_1$ and $C_2$ (PointSearch fails to find a smooth point up to height 10,000), at which point the intrinsic Magma function can form Elliptic Curves (it returns a smooth model $E_i$ over $L$, and a birational map from $C_i$ to $E_i$). Then we have

K<a> := QuadraticField(-2);
L<b> := PolynomialRing(K);
L<b> := ext<K | b^2 - 31>; 

A2<x,y> := AffineSpace(L, 2);

C1A := Curve(A2, 2*x^4 + 17*x^2 + 12 - y^2);
C2A := Curve(A2, x^4 - 17 - 2*y^2);

C1 := ProjectiveClosure(C1A);
C2 := ProjectiveClosure(C2A);

assert Genus(C1) eq 1;
assert Genus(C2) eq 1;

P1 := C1![1,b,1];
P2 := C2![1,2*a,1];

assert IsNonsingular(P1);
assert IsNonsingular(P2);

E1 := EllipticCurve(C1, P1);
E2 := EllipticCurve(C2, P2);

assert jInvariant(E1) ne jInvariant(E2);

which proves that $j(E_1) \neq j(E_2)$, so $E_1$ and $E_2$ are not isomorphic, and $C_1$ and $C_2$ are not birationally equivalent.