Conjugacy class representative of Aut(G), where $G$ is $M_{12}$ in GAP

Question

I am learning GAP,

Have a look at the following GAP code;

gap> G:=CharacterTable("M12.2");
CharacterTable( "M12.2" )
gap> ClassNames(G);
[ "1a", "2a", "2b", "3a", "3b", "4a", "5a", "6a", "6b", "8a", "10a", "11a", "2c", "4b", "4c", "6c", "10b", "10c", "12a", "12b", "12c" ]
gap> 

Suppose, I want to know the class representative of 12a. Is there a function which I can call ?

Answer 1

In this case, G is a character table, not a group (so your choice of the variable name G is misleading). The table is retrieved from the GAP Character Table Library, which stores precomputed tables. This guarantees that each time you retrieve it, the resulting table will have the same ordering of characters and conjugacy classes. But the resulting table will not have an underlying group, hence it will possess little information about the group. In particular, it will not have the ConjugacyClasses attribute.

One approach could be to construct the group and then compute its character table, as it was shown in where to find the tables of irreducible character of the sporadic simple groups and their automorphism groups? However, that may be time consuming, and may have different ordering of classes and characters in subsequent calls. Instead of that, I suggest to construct a group, and then link it with the character table retrieved from the library using CharacterTableWithStoredGroup:

gap> tl:=CharacterTable("M12.2");
CharacterTable( "M12.2" )
gap> M12:=MathieuGroup(12);
Group([ (1,2,3,4,5,6,7,8,9,10,11), (3,7,11,8)(4,10,5,6), (1,12)(2,11)(3,6)
(4,8)(5,9)(7,10) ])
gap> AM12:=AutomorphismGroup(M12);
<group with 4 generators>
gap> t:=CharacterTableWithStoredGroup(AM12,tl);
CharacterTable( <group of size 190080 with 4 generators> )
gap> ClassNames(t);
[ "1a", "2a", "2b", "3a", "3b", "4a", "5a", "6a", "6b", "8a", "10a", "11a",
  "2c", "4b", "4c", "6c", "10b", "10c", "12a", "12b", "12c" ]
gap> Position(ClassNames(t),"11a");
12

Now this is a conjugacy class of elements of order 11 in $Aut(M_{12})$:

gap> c:=ConjugacyClasses(t)[Position(ClassNames(t),"11a")];
[ (1,2,3,4,5,6,7,8,9,10,11), (3,7,11,8)(4,10,5,6), 
  (1,12)(2,11)(3,6)(4,8)(5,9)(7,10) ] -> 
[ (1,11,8,12,4,10,3,7,6,5,2), (1,4,11,7)(2,6,12,5), 
  (1,12)(2,7)(3,4)(5,8)(6,11)(9,10) ]^G

and this is a representative of this class:

gap> Representative(c);
[ (1,2,3,4,5,6,7,8,9,10,11), (3,7,11,8)(4,10,5,6), 
  (1,12)(2,11)(3,6)(4,8)(5,9)(7,10) ] -> 
[ (1,11,8,12,4,10,3,7,6,5,2), (1,4,11,7)(2,6,12,5), 
  (1,12)(2,7)(3,4)(5,8)(6,11)(9,10) ]

This notation means that this is an automorphism of $M_{12}$ which is induced by mapping corresponding elements of the 1st list to corresponding elements of the 2nd.