Defining a subgroup of $GL(2,7)$ in GAP

Question

Considering this resent post in which $|G|=42$, I am thinking of making this subgroup concrete in GAP environment. Maybe, if the structure of $G$ was known then, we would use an appropriate mapping for this aim by doing the inverse map. However, I started to examine the problem by doing some basic related codes as below, I got an error instead!

gap> g:=GeneralLinearGroup(2,Field(Z(7)));;
     e:=Elements(g);;
     f:=AllSubgroups(g);;
     Filtered(f, t->Order(f[t])=42);

Any suggestions? Thanks for the time.

---

Edit: I did a terrible job. The codes are changed as:

gap> g:=GeneralLinearGroup(2,Field(Z(7)));;
     f:=AllSubgroups(g);;
     e:=Elements(f);;
     Filtered(e, t->Order(t)=42);

Answer 1

With AllSubgroups, the correct form is shown below:

gap> g:=GL(2,7);
GL(2,7)
gap> f:=AllSubgroups(g);;
gap> Length(last);
1704
gap> h:=Filtered(f,t->Size(t)=42);;
gap> Length(h);
96
gap> h[1];
Group([ [ [ Z(7)^2, Z(7)^3 ], [ 0*Z(7), Z(7) ] ], 
  [ [ Z(7)^4, Z(7)^2 ], [ 0*Z(7), Z(7)^2 ] ], 
  [ [ Z(7), Z(7)^2 ], [ Z(7)^5, Z(7)^3 ] ] ])

However, thinking in terms of conjugacy classes may be more efficient for larger groups:

gap> g:=GL(2,7);
GL(2,7)
gap> cc:=ConjugacyClassesSubgroups(g);;
gap> Length(cc);
84
gap> cc42:=Filtered(cc,c->Size(Representative(c))=42);;
gap> Length(cc42);
12
gap> Representative(cc42[1]);
Group([ [ [ Z(7), 0*Z(7) ], [ 0*Z(7), Z(7)^2 ] ], 
  [ [ Z(7)^2, 0*Z(7) ], [ 0*Z(7), Z(7)^4 ] ], 
  [ [ Z(7)^0, Z(7)^5 ], [ 0*Z(7), Z(7)^0 ] ] ])