Finding characters fixed under an automorphism action

Question

I am trying to act on irreducible characters in GAP. The problem is the following: I have two groups S and K such that S acts on K via automorphisms of K. Hence, there is an action on the set of irreducible characters of K. I want to find the $S$-fixed irreducible characters. Unfortunately, I could not find any library that does this and I did not figure out a way to do this. Can you please help me?

Answer 1

The group acts by permuting the conjugacy classes and a character is fixed if it stays fixed under this permutation of the classes. To check this in GAP, it probably is easiest to compute permutations for the action on the conjugacy classes. For example (having the group $S=\langle(1,2,3,4)\rangle$ act on $K=A_5$):

gap> S:=Group((1,2,3,4));;
gap> K:=AlternatingGroup(5);;
gap> sact:=List(GeneratorsOfGroup(S),x->ConjugatorAutomorphism(K,x));
[ ^(1,2,3,4) ]
gap> acthom:=GroupHomomorphismByImages(S,Group(sact),
> GeneratorsOfGroup(S),sact);
[ (1,2,3,4) ] -> [ ^(1,2,3,4) ]

Now we have the setup, lets define an action that describes how elements of S (via the homomorphism acthom act on conjugacy classes of $K$, and calculate the permutation image:

gap> cl:=ConjugacyClasses(K);;
gap> classactionS:=function(class,s) return ConjugacyClass(K,
> Image(Image(acthom,s),Representative(class)));end;;
gap> clact:=Action(S,cl,classactionS);
Group([ (4,5) ])

Finally, we can determine which irreducible characters are fixed under these permutations -- we want that they stay the same when permuting the entries.

gap> fix:=Filtered(Irr(K),x->ForAll(GeneratorsOfGroup(clact),
> y->Permuted(x,y)=x));
[ Character( CharacterTable( Alt( [ 1 .. 5 ] ) ), [ 1, 1, 1, 1, 1 ] ),
  Character( CharacterTable( Alt( [ 1 .. 5 ] ) ), [ 4, 0, 1, -1, -1 ] ),
  Character( CharacterTable( Alt( [ 1 .. 5 ] ) ), [ 5, 1, -1, 0, 0 ] ) ]