Finding the Fourier transform of an equation

Question

I need to calculate the Fourier transform, but I don't know how to do it. Help me, please!

Answer 1

I'll use Mathematica to be pragmatic & quick here.

Let's Fourier-transform the three terms separately:

first term

F1[k_] = FourierTransform[1, x, k]

Sqrt[2π] DiracDelta[k]

second term

F2[k_] = Assuming[Element[k, Reals], 
  FourierTransform[Sinc[x]^2, x, k] // PiecewiseExpand // FullSimplify]

$$ \begin{cases} \frac{1}{2} \sqrt{\frac{\pi }{2}} (k+2) & -2\leq k<0 \\ -\frac{1}{2} \sqrt{\frac{\pi }{2}} (k-2) & 0\leq k\leq 2 \end{cases} $$

third term

Let's interchange the integration with the Fourier transformation without proving that it's legal. First Fourier-transform the integrand,

f3[k_, z_] = Assuming[Element[k, Reals] && z >= 1, 
  FourierTransform[Sin[x z]/z Sinc'[x], x, k] // PiecewiseExpand // FullSimplify]

$$ \begin{cases} -\frac{\sqrt{\frac{\pi }{2}}}{2} & k+1=z\land k+z=1 \\ \frac{\sqrt{\frac{\pi }{2}} (k-z)}{4 z} & (k+1=z\lor k=z+1)\land k+z>1 \\ \frac{\sqrt{\frac{\pi }{2}} (k-z)}{2 z} & z<k+1\land k<z+1 \\ -\frac{\sqrt{\frac{\pi }{2}} (k+z)}{2 z} & -1<k+z<1 \\ -\frac{\sqrt{\frac{\pi }{2}} (k+z)}{4 z} & (k+z+1=0\lor k+z=1)\land k+1<z \end{cases} $$

then do the integral over $z$:

F3[k_] = Assuming[Element[k, Reals], 
  Integrate[f3[k, z], {z, 1, ∞}] // FullSimplify]

$$ \begin{cases} -\frac{1}{2} \sqrt{\frac{\pi }{2}} \left(k \log \left(\frac{k-1}{k+1}\right)+2\right) & k\leq -2 \\ -\frac{1}{2} \sqrt{\frac{\pi }{2}} k (\log (1-k)-1) & -2<k\leq 0 \\ \frac{1}{2} \sqrt{\frac{\pi }{2}} k (\log (k+1)-1) & 0<k\leq 2 \\ \frac{1}{2} \sqrt{\frac{\pi }{2}} \left(k \log \left(\frac{k+1}{k-1}\right)-2\right) & \text{True} \end{cases} $$

all terms together

F[k_] = Assuming[Element[k, Reals], 
  F1[k] + F2[k] + F3[k] // PiecewiseExpand // FullSimplify]

$$ \begin{cases} \frac{1}{4} \left(4 \sqrt{2 \pi } \delta (k)-\sqrt{2 \pi } k \log \left(\frac{k-1}{k+1}\right)-2 \sqrt{2 \pi }\right) & k<-2 \\ \frac{1}{4} \left(4 \sqrt{2 \pi } \delta (k)+\sqrt{2 \pi } k-\sqrt{2 \pi } k \log \left(\frac{k-1}{k+1}\right)\right) & k=-2 \\ \frac{1}{4} \left(4 \sqrt{2 \pi } \delta (k)+2 \sqrt{2 \pi } k-\sqrt{2 \pi } k \log (1-k)+2 \sqrt{2 \pi }\right) & -2<k<0 \\ \frac{1}{4} \left(4 \sqrt{2 \pi } \delta (k)-\sqrt{2 \pi } k \log (1-k)+2 \sqrt{2 \pi }\right) & k=0 \\ \frac{1}{4} \left(4 \sqrt{2 \pi } \delta (k)-2 \sqrt{2 \pi } k+\sqrt{2 \pi } k \log (k+1)+2 \sqrt{2 \pi }\right) & 0<k\leq 2 \\ \frac{1}{4} \left(4 \sqrt{2 \pi } \delta (k)+\sqrt{2 \pi } k \log \left(\frac{k+1}{k-1}\right)-2 \sqrt{2 \pi }\right) & \text{True} \end{cases} $$

Make a plot of the Fourier transform, keeping in mind that we cannot see the Dirac $\delta$-function at the origin:

Plot[F[k], {k, -10, 10}, PlotRange -> All]