Generalizing Ramanujan cubic denesting formula to higher powers

Question

We have the following theorems for denesting radicals of degree 2 and 3 :

Denesting theorem for degree 2 :

If $\alpha, \beta$ are the roots of the equation,

\begin{equation} x^2-ax+b = 0 \end{equation}

then

\begin{equation} \sqrt{\alpha} + \sqrt{\beta} = \sqrt{a + 2\sqrt{b}} \end{equation}

This theorem can easily be proved by using the Vieta formulas, and squaring both sides. It tells us that such nested radicals can be denested when the determinant is a perfect square ($a^2-4b^2 = n^2$).

Denesting theorem for degree 3 (from Ramanujan) :

If $\alpha, \beta,\gamma$ are the roots of the equation,

\begin{equation} x^3-ax^2+bx - 1 = 0 \end{equation}

then

\begin{align} \sqrt[3]{\alpha} + \sqrt[3]{\beta}+ \sqrt[3]{\gamma} &= \sqrt[3]{a + 6 + 3t} \\ \sqrt[3]{\alpha\beta}+\sqrt[3]{\beta\gamma}+\sqrt[3]{\gamma\alpha}&=\sqrt[3]{b+6+3t} \end{align}

where $t$ satisfy the equation

\begin{equation} t^3−3(a+b+3)t−(ab+6(a+b)+9)=0 \end{equation}

This theorem is well proved here, and allows to produce many nice identities, such as, $$\sqrt[3]{\cos\tfrac {2\pi}7}+\sqrt[3]{\cos\tfrac {4\pi}7}+\sqrt[3]{\cos\tfrac {8\pi}7}=\sqrt[3]{\tfrac 12\left(5-3\sqrt[3]7\right)}$$

Questions :

1. How to generalize such denesting theorems to higher powers ?
2. What nice identities can we generate ?

Let's take the case for degree 4. Let $\alpha, \beta,\gamma,\delta$ are the roots of the equation,

\begin{equation} x^4-ax^3+bx^2 -cx + 1 = 0 \end{equation}

then

\begin{equation} \sqrt[4]{\alpha} + \sqrt[4]{\beta}+ \sqrt[4]{\gamma} + \sqrt[4]{\delta} = \sqrt[4]{a + 4t + 6u + 12v} \end{equation}

where $t,u,v$ are

\begin{align} t &= \sum_{perm} \sqrt[4]{\alpha}^3\sqrt[4]{\beta} \\ u &= \sum_{perm} \sqrt[4]{\alpha}^2\sqrt[4]{\beta}^2 \\ v &= \sum_{perm} \sqrt[4]{\alpha}^2\sqrt[4]{\beta}\sqrt[4]{\gamma} \end{align}

which we can find by taking the LHS to the power 4, and using the multinomial theorem. It would be very nice if the $t,u,v$ where also to satisfy a polynomial equation of degree 4 (does it ?). If it so then we would have a theorem similar to the cubic and we could generate new identities.

However to verify if $t,u,v$ satisfy a quartic by elevating them to the power 4 is algebraically heavy and I have not been able to do it. I tried to use symmetrical polynomials to simplify computations.

Answer 1

I used the following PARI/GP code to find that, for $x^4-6x^3+11x^2-7x+1 = (x-1)(x^3-5x^2+6x-1)$, with real roots $\,0<\alpha<\beta<\gamma<\delta,\,$ then $s,t$ and $v$ are roots of irreducible $12$th degree polynomials while $u$ is a root of the cubic $x^3-3x^2-25x-29$ where $$ s := \sqrt[4]{\alpha} + \sqrt[4]{\beta}+ \sqrt[4]{\gamma} + \sqrt[4]{\delta} = \sqrt[4]{a + 4t + 6u + 12v + 24} $$ and where $\,t,u,v\,$ are homogeneous sums defined in the question.

default(realprecision, 200); /* use 200 decimal digit precision */
[a,b,c] = [6,11,7];
/* compute roots of the fourth degree polynomial */
r = polroots(x^4 - a*x^3 + b*x^2 - c*x + 1);
/* give names to the four polynomial roots */
[al,be,ga,de] = r; 
/* give names to the 4th root of these values */
[Al,Be,Ga,De] = vector(4,n, r[n]^.25); 

/* compute some symmetric homogeneous polynomial sums */
s = Al + Be + Ga + De;
t = {(Al^3*Be + Al*Be^3) + (Al^3*Ga + Al*Ga^3) + (Be^3*Ga + Be*Ga^3) +
    (Al^3*De + Al*De^3) + (Be^3*De + Be*De^3) + (Ga^3*De + Ga*De^3)};
u = Al^2*Be^2 + Al^2*Ga^2 + Al^2*De^2 + Be^2*Ga^2 + Be^2*De^2 + Ga^2*De^2;
v = {Al^2*(Be*Ga + Be*De + De*Ga) + Be^2*(Al*Ga + Al*De + De*Ga) +
    Ga^2*(Al*Be + Al*De + Be*De) + De^2*(Al*Be + Al*Ga + Be*Ga)};

/* find their irreducible polynomial */
ps = algdep(s,12,120); print("ps = ",ps);
/* ps = x^12 - 12*x^11 + 64*x^10 - 224*x^9 + 596*x^8 - 1184*x^7 +
 1744*x^6 - 2016*x^5 + 1408*x^4 + 512*x^3 - 1664*x^2 + 768*x - 64 */
pt = algdep(t,12,120); print("pt = ",pt);
/* pt = x^12 - 184*x^10 - 1032*x^9 + 3412*x^8 + 36096*x^7 + 12272*x^6 - 
 475776*x^5 - 776256*x^4 + 2883456*x^3 + 7148416*x^2 - 7915008*x - 26828096 */ 
pu = algdep(u,3,120);  print("pu = ",pu);
/* pu = x^3 - 3*x^2 - 25*x - 29 */
pv = algdep(v,12,120); print("pv = ",pv);
/* pv = x^12 - 104*x^10 - 664*x^9 - 2204*x^8 - 6528*x^7 - 13616*x^6 -
 19776*x^5 - 36416*x^4 - 19584*x^3 - 45312*x^2 - 3072*x - 18752 */

/* verify that the polynomials are irreducible */
print([polisirreducible(x) | x <- [ps,pt,pu,pv]])
/* [1, 1, 1, 1] */

/* verify that the roots satisfy the polynomials to high precision */
print(round(10^196*[subst(z[1],x,z[2]) | z <- [[ps,s],[pt,t],[pu,u],[pv,v]]]))
/* [0, 0, 0, 0] */

/* verify that s^4 = a + 4*t + 6*u + 12*v + 24 to high precision */
print(round(10^208*(s^4 - (a + 4*t + 6*u + 12*v + 24))))
/* 0 */

I did not try to find a simpler example, but I am sure one can be found by a simple search.