How to find that limit by mathematica?

Question

Limit[Sum[2(2k)^(1/(2k))-k^(1/k),{k,n+1,2n}]-n, n -> ∞]

to solve by hand, $$\sqrt[y]y=e^{\frac{\ln y}{y}}\sim1+\frac{\ln y}{y}$$ $$2\sqrt[2k]{2k}-\sqrt[k]k\sim1+\frac{\ln2}{k}$$ $$\sum_{k=n+1}^{2n}\left(2\sqrt[2k]{2k}-\sqrt[k]k\right)\sim n+\ln2\sum_{k=n+1}^{2n}\frac1k\sim n+\ln 2 \, \int_{n+1}^{2n}\dfrac{1}{t}dt$$ $$\lim_{n\to \infty}\left(\sum_{k=n+1}^{2n}\left(2\sqrt[2k]{2k}-\sqrt[k]k\right)-n\right)=\ln^22$$

Answer 1

As I wrote, this is rather math than Mathematica. Let me improve the Bob Hanlon's approach. First,

Series[2 (2 k)^(1/(2 k)) - k^(1/k), {k, Infinity, 1}]

$ O\left(\left(\frac{1}{k}\right)^2\right)+\frac{\log (2)}{k}+1$

Second, the sum of $O(k^{-2})$ over $k$ from $n+1$ to $2n$ is $O(n^{-1})$ so the one tends to zero as $n$ approaches $\infty$. We need estimates to ground it and this is math. Now

Sum[Normal[Series[2 (2 k)^(1/(2 k)) - k^(1/k), {k, Infinity, 1}]], {k,
n + 1, 2*n}] - n

$ \log (2) \psi ^{(0)}(2 n+1)-\log (2) \psi ^{(0)}(n+1)$

The last step is

Limit[%, n -> Infinity]

$\log ^2(2)$

To be sure,

N[%]

$ 0.480453$

Answer 2

It looks like a very complicated sum but it does seem to slow done enough to estimate its value and may converge!

Mathematica is not able to solve it analytically in my attempt.

First, a few things to note:

• n-th root of x in real domain is represented by Surd in Mathematica.
• Secondly, you need to take the discrete limit over the integers here.

Now you can try the analytical approach as follows:

ClearAll[f];
f[n_]:=Sum[2Surd[2k,2k]-Surd[k,k],{k,n+1,2n}]-n;

DiscreteLimit[
    f[n],
    n->∞
]

Maybe someone here can help with how to make Mathematica get to the analytical limit.

But we can estimate its value:

list=Table[
    N@f[n],
    {n,1,1000}
];

ListPlot[list,PlotRange->All]
ListPlot[Differences@list,PlotRange->All]

Estimation:

N@f[10000]
N@f[100000]
N@f[1000000]

0.479474

0.480298

0.48043