Parameterization of Equation with Gaussian Integer

Question

I'd like to ask how to get the parameterization to this equation: $3z_1^2+z_2^2=156$, where $z_1$ and $z_2$ are both Gaussian integers.

More generally, is there any parameterization to the general equation $az_1^2+bz_2^2=c$?

Answer 1

Here is a discussion around solving $$3x^2+y^2=156\ ,\qquad x,y\in\Bbb Z[i]\ ,$$ based on the factorization of $156$ in the ring $R$ of integers of the number field $$K=\Bbb Q(\sqrt{-1},\sqrt{-3})=\Bbb Q(i,\sqrt 3)\ .$$ I am using $x,y$ instead of the indexed $z$-variables, since it is comfortable to use further the implicit notations $x=x_1+ix_2$, $y=y_1+iy_2$, and avoiding too much indices makes typing simpler.

Note that any solution of the given equation can be rewritten $$ (y+x\sqrt{-3}) (y-x\sqrt{-3}) =156\ .$$ So we have to find among all factors of $156\in R=\mathcal O_K$ the suitable ones (that have coefficients in $\Bbb Z$ w.r.t. the basis $\{1,i,\sqrt 3,i\sqrt{3}\}$). Note that $R=\mathcal O_K$ is a unique factorization domain. This, and some further steps can be get using sage, the sage code is generally object oriented, structural, and easily readable for mathematicians, i hope its application here by my typing hand does not suggest the contrary, the fields $Q=\Bbb Q(i)$, $L=Q(\sqrt{-3})$, and $K=\Bbb Q(i+\sqrt3)\cong L$ will be introduced, and some properties of them are questioned...

sage: R.<x> = PolynomialRing(QQ)
sage: Q.<j> = QuadraticField(-1)
sage: L.<s> = Q.extension( x^2+3 )
sage: Q
Number Field in j with defining polynomial x^2 + 1
sage: L
Number Field in s with defining polynomial x^2 + 3 over its base field
sage: j^2, s^2
(-1, -3)
sage: L.is_unique_factorization_domain()
True
sage: S.<X> = PolynomialRing(L)
sage: (X-j-j*s)*(X-j+j*s)*(X+j-j*s)*(X+j+j*s)
X^4 - 4*X^2 + 16
sage: K.<a> = NumberField( x^4 - 4*x^2 + 16 )
sage: a.complex_embedding()
-1.73205080756888 - 1.00000000000000*I
sage: K.is_unique_factorization_domain()
True
sage: K.class_number()
1
sage: K.unit_group()
Unit group with structure C12 x Z of Number Field in a 
with defining polynomial x^4 - 4*x^2 + 16
sage: L.unit_group()
Unit group with structure C12 x Z of Number Field in s
with defining polynomial x^2 + 3 over its base field
sage: K.units()
(1/8*a^3 - 1/2*a + 1,)
sage: (1/8*a^3 - 1/2*a + 1).norm()
1
sage: L.units()
(-1/2*j*s + 1/2*j + 1,)
sage: (-1/2*j*s + 1/2*j + 1).norm()
1

Let us also ask for the factors of $156\in \mathcal O_L$, and their multiplicities...

sage: print "%4s %-30s %4s %s" % ( 'Mul', 'Factor', 'Norm', 'Norm/Q' )
sage: for fact, mul in L(156).factor():
....:     print ( "%4s %-30s %4s %s"
....:             % (mul, fact, fact.norm(), fact.relative_norm()) )
....:     

 Mul Factor                         Norm Norm/Q

   4 (-1/2*j - 1/2)*s - 1/2*j - 1/2    4 2*j
   2 1/2*s + 3/2                       9 3
   1 -1/2*s - j + 3/2                 13 -3*j + 2
   1 1/2*j*s - 3/2*j + 1              13 -3*j - 2
   1 (-1/2*j + 1/2)*s + 1/2*j - 3/2   13 -3*j + 2
   1 (1/2*j + 1/2)*s - 1/2*j - 3/2    13 3*j + 2

Some results were manually rearranged to fit in the shown width.

Humanly, this means we have the following factors that appear in the decomposition of $156$:

$$ \begin{aligned} f_1 &=\frac 12(1+i+\sqrt{-3}+i\sqrt{-3}) &&\sim \bar f_1\ , &&\text{ order }4\ ,\\ f_2 &=\sqrt{-3}&&\sim \bar f_2\ , &&\text{ order }2\ ,\\[2mm] f_3 &=\frac 12(3-\sqrt{-3})-i &&\sim \bar f_5\ , &&\text{ order }1\ ,\\ f_4 &=\frac 12(3-\sqrt{-3})+i&&\sim \bar f_6\ , &&\text{ order }1\ ,\\[2mm] f_5 &=\frac 12(-3+\sqrt{-3}(1-i)+i)&&\sim \bar f_3\ , &&\text{ order }1\ ,\\ f_6 &=\frac 12(-3+\sqrt{-3}(1+i)-i)&&\sim \bar f_4\ , &&\text{ order }1\ , \end{aligned} $$ and now we have to group them w.r.t. the Galois conjugation which maps $i\to i$, $\sqrt{-3}\to-\sqrt{-3}$. A solution of $y^2+3x^2=156$ in integers corresponds to a solution for the relative norm problem $$ N_{L:\Bbb Q(i)}(y+x\sqrt{-3})=(y+x\sqrt{-3})(y-x\sqrt{-3})=156\ , $$ and the two factors contain $(L:\Bbb Q(i))$-conjugated prime factors. These factors are those from above, there may also appear a unit, and we have a classification for the unit group of the field. It has a $12$--torsion part generated by the fourth roots of the unit $1,i,-1,-i$, and the sixth roots of the unit, $1,u,u^2,u^3=-1, -u,-u^2$, where $u=\frac 12(1+\sqrt{-3})$, and the two groups of order $4$, resp. $6$ have the obvious subgroup of order two, $\pm 1$ in common. It also has a free part, in the code we have the generating unit $$ W = 1+\frac i2(1-\sqrt{-3})\ , $$ and its first few powers are:

sage: for k in range(19):
....:     print "W^%2s = %s" % ( k, W^k )
....:     
W^ 0 = 1
W^ 1 = -1/2*j*s + 1/2*j + 1
W^ 2 = (-j + 1/2)*s + j + 3/2
W^ 3 = (-3/2*j + 3/2)*s + 5/2*j + 5/2
W^ 4 = (-2*j + 7/2)*s + 6*j + 7/2
W^ 5 = (-2*j + 15/2)*s + 13*j + 7/2
W^ 6 = 15*s + 26*j
W^ 7 = (15/2*j + 28)*s + 97/2*j - 13
W^ 8 = (28*j + 97/2)*s + 84*j - 97/2
W^ 9 = (153/2*j + 153/2)*s + 265/2*j - 265/2
W^10 = (181*j + 209/2)*s + 181*j - 627/2
W^11 = (390*j + 209/2)*s + 181*j - 1351/2
W^12 = 780*j*s - 1351
W^13 = (2911/2*j - 390)*s - 1351/2*j - 2521
W^14 = (2521*j - 2911/2)*s - 2521*j - 8733/2
W^15 = (7953/2*j - 7953/2)*s - 13775/2*j - 13775/2
W^16 = (5432*j - 18817/2)*s - 16296*j - 18817/2
W^17 = (5432*j - 40545/2)*s - 35113*j - 18817/2
W^18 = -40545*s - 70226*j

Not all of them have coefficients in $\Bbb Z[i]$, but $W^{6k}\in\Bbb Z[i]$ is a fact.

Now we can proceed as follows. We find all the solutions using a unit and some (suitably chosen) factors among $f_1,\dots, f_6$. These provide a finite set of solutions. We multiply them with powers of $W$ and get algebraic integers $y+x\sqrt{-3}$ of norm $156$. So the general solution is of the form: $$ y + x\sqrt{-3} = u\cdot f_1^2\, f_2\, f_{3\text{ or }5}\, f_{4\text{ or }6}\cdot W^k\ , $$ where $u$ is a unit (among $12$) and $k\in \Bbb Z$. We can pass from $(x,y)$ to a solution with real part of $x,y$ both $>0$ (by using powers of $i$).

Here are some values for $x,y\in\Bbb Z[i]$, computed via sage:

Q.<j> = QuadraticField(-1)
R.<X> = Q[]
L.<s> = Q.extension(X^2+3)
f1, f2, f3, f4, f5, f6 = [ f for f, mul in L(156).factor() ]
u = (1+s)/2
units = list(set([ v1*v2 for v1 in [1,j,-1,-j] for v2 in [1,u,u^2,-1,-u,-u^2] ]))
W = L.units()[0]

for k in [0..12]:
    for v in units:
        for f35 in [f3, f5]:
            for f46 in [f4, f6]:
                xi = v * f1^2 * f2 * f35 * f46 * W^k
                xibar = 2*xi.lift().coefficients()[0] - xi
                y, x  = (xi+xibar)/2, (xi-xibar)/2/s
                if (y^2 + 3*x^2 == 156) and QQ(y + y.conjugate()) > 0 and QQ(x + x.conjugate()) > 0:
                    print "y = %-15s | x = %-15s | y^2 + 3x^2 = %3s" % (y, x, y^2 + 3*x^2)

Results:

y = 12              | x = 2               | y^2 + 3x^2 = 156
y = 3*j + 12        | x = -3*j + 4        | y^2 + 3x^2 = 156
y = -3*j + 12       | x = 3*j + 4         | y^2 + 3x^2 = 156
y = 3               | x = 7               | y^2 + 3x^2 = 156
y = 9               | x = 5               | y^2 + 3x^2 = 156
y = 21*j + 6        | x = -3*j + 14       | y^2 + 3x^2 = 156
y = 18*j + 33       | x = -18*j + 11      | y^2 + 3x^2 = 156
y = 6*j + 15        | x = -6*j + 5        | y^2 + 3x^2 = 156
y = 6*j + 24        | x = -12*j + 4       | y^2 + 3x^2 = 156
y = 15*j + 18       | x = -9*j + 10       | y^2 + 3x^2 = 156
y = 60*j + 63       | x = -36*j + 35      | y^2 + 3x^2 = 156
y = 84*j + 21       | x = -12*j + 49      | y^2 + 3x^2 = 156
y = 27*j + 48       | x = -27*j + 16      | y^2 + 3x^2 = 156
y = 24*j + 84       | x = -48*j + 14      | y^2 + 3x^2 = 156
y = 69*j + 120      | x = -69*j + 40      | y^2 + 3x^2 = 156
y = 225*j + 234     | x = -135*j + 130    | y^2 + 3x^2 = 156
y = 102*j + 177     | x = -102*j + 59     | y^2 + 3x^2 = 156
y = 90*j + 312      | x = -180*j + 52     | y^2 + 3x^2 = 156
y = 315*j + 78      | x = -45*j + 182     | y^2 + 3x^2 = 156
y = 258*j + 447     | x = -258*j + 149    | y^2 + 3x^2 = 156
y = 381*j + 660     | x = -381*j + 220    | y^2 + 3x^2 = 156
y = 336*j + 1164    | x = -672*j + 194    | y^2 + 3x^2 = 156
y = 1176*j + 291    | x = -168*j + 679    | y^2 + 3x^2 = 156
y = 840*j + 873     | x = -504*j + 485    | y^2 + 3x^2 = 156
y = 963*j + 1668    | x = -963*j + 556    | y^2 + 3x^2 = 156
y = 3594*j + 6225   | x = -3594*j + 2075  | y^2 + 3x^2 = 156
y = 1254*j + 4344   | x = -2508*j + 724   | y^2 + 3x^2 = 156
y = 3135*j + 3258   | x = -1881*j + 1810  | y^2 + 3x^2 = 156
y = 4389*j + 1086   | x = -627*j + 2534   | y^2 + 3x^2 = 156
y = 1422*j + 2463   | x = -1422*j + 821   | y^2 + 3x^2 = 156
y = 13413*j + 23232 | x = -13413*j + 7744 | y^2 + 3x^2 = 156
y = 4680*j + 16212  | x = -9360*j + 2702  | y^2 + 3x^2 = 156
y = 16380*j + 4053  | x = -2340*j + 9457  | y^2 + 3x^2 = 156
y = 11700*j + 12159 | x = -7020*j + 6755  | y^2 + 3x^2 = 156
y = 5307*j + 9192   | x = -5307*j + 3064  | y^2 + 3x^2 = 156

---

The general case depends on the way to capture a bigger class number, the computation of units is relatively simpler to get calculated. But note that the units can accidentally a "very big height" and hard to compute in special cases.