plotting cones and space curves using Maple

Question

A curve $\cal{C}$ is given by the parametric equation $$ {\bf r}(t) = (e^t\cos t, e^t\sin t, e^t-1)\;,\quad 0\leq t\leq 2\pi\;. $$ Using Maple, I would like to sketch the curve $\cal{C}$ and the cone $x^2+y^2=(z+1)^2$ on the same set of axes. I have tried several options to no avail. Any suggestions, please?

Answer 1

A rough surface can be obtained with,

plots:-display(
  plots:-spacecurve([exp(t)*cos(t),exp(t)*sin(t),exp(t)-1],t=0..2*Pi,
                    color=red),
  plots:-implicitplot3d(x^2+y^2=(z+1)^2,x=-10..10,y=-10..10,z=0..9,
                        grid=[30,30,30],style=patchnogrid,
                        transparency=0.5),
  view=[-10..10,-10..10,0..9] );

The quality of the surface above is influenced by the grid option, but using a much finer grid degrades the performance (and responsiveness of the Standard GUI while manually rotating with the mouse, etc).

A smoother surface with better computational performance and GUI responsiveness can be obtained with a change of coordinates for generating the surface.

 plots:-display(
   plots:-spacecurve([exp(t)*cos(t),exp(t)*sin(t),exp(t)-1],t=0..2*Pi,
                     color=red),
   plot3d(r+1,theta=0..2*Pi,r=0..9,coords=cylindrical,
          style=patchnogrid,transparency=0.5),
   view=[-10..10,-10..10,0..9] );