Understanding the structure of a module over a group algebra

Question

Suppose one has a permutation group $G$ acting on the set $[n] = \{1, 2, \ldots, n\}$, which extends naturally for any field $F$ to a $FG$-module structure on the set $F[n]^k$ of formal $F$-linear combinations of $k$-tuples of $[n]$, with $G$ acting component-wise.

What are the tools that can be used to study the resulting module? From my (admittedly weak) understanding, representation theory is used to understand the structure of groups, not of particular modules over them. Is $FG$ treated as an arbitrary ring, or can more be said because of its well-defined structure?

Answer 1

Some areas of representation theory focus on the entire collection of representations at once, but not all areas do.

Luckily the specific module you are looking at is very famous, it is the Young module used in some discussions to define the Specht modules you asked about before.

If $F$ is a field of characteristic $0$, then character theory works very well (and is easy to use in GAP). To create the Young module:

$$1_{S_k \times S_{n-k}}{\uparrow} S_n$$

in gap, you can either use the definition of Young module, or your definition. In GAP your definition is much faster, but the first definition is more commonly used in textbooks.

young:=function(n,k)
  return InducedClassFunction(
    TrivialCharacter( DirectProduct(SymmetricGroup(k),SymmetricGroup(n-k))),
    SymmetricGroup(n) );
end;
tuples:=function(n,k)
  return PermutationCharacter( SymmetricGroup(n), Combinations([1..n],k), OnSets );
end;

Now to decompose it into a direct sum of Specht modules use the inner product:$$[\chi,\phi]=\frac{1}{|G|} \sum_{g\in G} \chi(g),\phi(g^{-1})$$ where $\phi$ is your $k$-tuples permutation / Young module, $\chi \in \operatorname{Irr}(G)$ is an irreducible / Specht module, and $[\chi,\phi]$ is the non-negative integer describing how many direct summands of $\phi$ are isomorphic to $\chi$ in any indecomposable direct sum decomposition of $\phi$ in characteristic $0$. In GAP one does this:

n:=8; k:=3;
sym := SymmetricGroup(n);
ct := CharacterTable("Symmetric",n);
CharacterTableWithStoredGroup( sym, ct );
phi := tuples(n,k);
MatScalarProducts(Irr(ct),[phi]);

which gives the output

[ [ 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 1, 1, 1 ] ]

meaning that only the last few Specht modules are involved. We probably want to know which ones, so let's tell GAP to name things appropriately:

SetCharacterNames(ct,List(CharacterParameters(ct),x->JoinStringsWithSeparator(x[2],".")));
describe := function(ct,phi)
  return JoinStringsWithSeparator( Filtered(
    List( [1..NrConjugacyClasses(ct)], function(i)
      local chi, mult;
      chi := Irr(ct)[i];
      mult := ScalarProduct( ct, chi, phi );
      if mult > 1 then return Concatenation( String(mult),"x",CharacterNames(ct)[i] );
      elif mult = 1 then return CharacterNames(ct)[i];
      else return "";
      fi;
    end ), x -> x <> "" ), " + " );
end;
describe(ct,tuples(n,k));

`` which gives output:

"5.3 + 6.2 + 7.1 + 8"

Now it turns out these numbers (0,0,...,0,1,0,1,1,1) are very famous. They are the Littlewood-Richardson coefficients $c^{[k,n-k]}_{[k],[n-k]}$ where $\chi$ is usually represented as a partition of $n$, and $[k]$ is the trivial partition of $k$ representing the trivial character, and similarly for $[n-k]$.

Now suppose you want a smaller field, like $\mathbb{F}_2$. Then you'll need to use the MeatAxe or related software (available in GAP) to chop up the Specht modules. Since Specht modules tend to have large dimension, this is not normally done for large $n$, but rather one works in Hecke algebras using “condensation” which replaces the simple modules with simple modules over different (Morita equivalent) rings where the simple modules have small dimension. Ideally one wants the simple modules to have dimension 1, a so-called basic algebra, but this is rarely feasible. If $n \leq 19$, then you can use GAP's DecompositionMatrix to do this. Let me know if you want to see code to do this.

I suspect combinatorics people would have better answers. I just view the symmetric group as a random finite group, but many of these calculations have combinatorial interpretations.