What is the bracket polynomial $<W>$ of the Whitehead link $W$?

Question

$W$ has 6 crossings so there should be $2^6=64$ states of the knot diagram for $W$ but how do I find the bracket polynomial (Kauffman bracket) of the link $W$?

Answer 1

For a computer, 64 states is nothing. Consider the following decomposition of the Whitehead link into crossings. The green labels should be thought of as being at some point along each arc, and a crossing is described by the labeled points it is connected to.

The following Mathematica code is adapted from The Knot Atlas.

ClearAll[P, X, A];
SetAttributes[P, {Orderless}];
KB[link_] := With[{d = -A^2 - A^-2},
   Simplify[d^-1 Expand[link
        /. {X[a_, b_, c_, d_] :> 
          A P[a, b] P[c, d] + A^-1 P[a, d] P[b, c]}]
     //. {P[a_, a_] :> d, P[a_, b_]^2 :> d, 
      P[a_, b_] P[b_, c_] :> P[a, c]}]];

P[a,b] is a path connecting vertices a and b, and X[a,b,c,d] is a crossing involving vertices a,b,c,d (in counterclockwise order around the crossing) with a,c the understrand and b,d the overstrand.

Then,

KB[X[2, 6, 1, 7] X[5, 3, 6, 2] X[10, 3, 11, 4]
   X[9, 1, 10, 8] X[5, 12, 4, 11] X[7, 9, 8, 12]]

gives $1 + A^{-8} - 2A^{-4} - 2 A^4 + A^8 - A^{12}$.

Of course, this depends on the framing of the link. I just chose a diagram based on the information that you thought the Whitehead link had six crossings (there is also a five crossing diagram).

If you insist on doing it by hand, you could decompose it into nested 2-tangles, as in the following diagram. Figure out the expansion of twisted pairs of strands, then stick those together to form the larger 2-tangle on the right (this will take 4 terms in the expansion and yield 2 terms once simplified), then stick it to the 2-tangle on the left (4 terms in the expansion). Much better than 64 states!