Will this strategy give me the whole subgroup lattice?

Question

I have to do the following question

Consider the semidihedral group $$QD_{16} = \langle\sigma, \tau|\sigma^8=\tau^2=1, \sigma \tau = \tau \sigma^3\rangle$$ This group has three subgroups: $\langle\sigma, \tau\rangle \cong D_8, \langle\sigma\rangle \cong Z_8,$ and $\langle\sigma^2, \sigma \tau\rangle \cong Q_8.$ Every proper subgroup of $QD_{16}$ is a subgroup of one of these three subgroups. Draw the subgroup lattice for $QD_{16}$.

My strategy was to draw subgroup lattices for $D_8$, $Z_8$, and $Q_8$. Then, (for example) for each subgroup in $Q_8$, I tried to find a corresponding subgroup in $\langle\sigma^2, \sigma \tau\rangle \cong Q_8.$ Thus, at the end, my lattice for $QD_{16}$ looked pretty much like the lattices of $D_8$, $Q_8, Z_8$ put next to each other to each other, except they were of course all connected at the top to $G$ and at the bottom to $\langle 1\rangle$. Is this the correct strategy, or am I potentially missing some subgroups?

Answer 1

Here is a sage code showing the (information on the subgroups, and the needed) lattice.

sage: G = SemidihedralGroup(4)
sage: G.order() == 2^4
True
sage: subgroups = G.subgroups()
sage: subgroups.sort( lambda H1, H2:    cmp( H1.order(), H2.order() ) )
sage: for H in subgroups:
....:     print H.order(), H.structure_description(), H.gens(), 'commutative' if H.is_commutative() else ''
....:     
1 1 [()] commutative
2 C2 [(1,5)(2,6)(3,7)(4,8)] commutative
2 C2 [(2,4)(3,7)(6,8)] commutative
2 C2 [(1,3)(2,6)(5,7)] commutative
2 C2 [(1,5)(2,8)(4,6)] commutative
2 C2 [(1,7)(3,5)(4,8)] commutative
4 C2 x C2 [(2,4)(3,7)(6,8), (1,5)(2,6)(3,7)(4,8)] commutative
4 C2 x C2 [(1,5)(2,6)(3,7)(4,8), (1,7)(3,5)(4,8)] commutative
4 C4 [(1,3,5,7)(2,4,6,8), (1,5)(2,6)(3,7)(4,8)] commutative
4 C4 [(1,2,5,6)(3,8,7,4), (1,5)(2,6)(3,7)(4,8)] commutative
4 C4 [(1,4,5,8)(2,7,6,3), (1,5)(2,6)(3,7)(4,8)] commutative
8 D4 [(2,4)(3,7)(6,8), (1,5)(2,6)(3,7)(4,8), (1,7)(3,5)(4,8)] 
8 C8 [(1,2,3,4,5,6,7,8), (1,3,5,7)(2,4,6,8), (1,5)(2,6)(3,7)(4,8)] commutative
8 Q8 [(1,3,5,7)(2,4,6,8), (1,4,5,8)(2,7,6,3), (1,5)(2,6)(3,7)(4,8)] 
16 QD16 [(2,4)(3,7)(6,8), (1,2,3,4,5,6,7,8), (1,5)(2,6)(3,7)(4,8), (1,7)(3,5)(4,8)] 

The above $15$ subgroups are denoted simply by $0,1,2,\dots, 14$. We build the oriented graph.

sage: labels = range(len(subgroups))
sage: all_edges = []
sage: for j in labels:
....:     J = subgroups[j]
....:     elementsJ = set(J.list())
....:     for k in labels:
....:         if k<= j:    continue
....:         K = subgroups[k]
....:         elementsK = set(K.list())
....:         if elementsJ.issubset(elementsK):
....:             all_edges.append( [k, j] )
....:             
sage: edges = []
sage: for edge in all_edges:
....:     j, n = edge
....:     ok = True    # so far
....:     for k in labels:
....:         if [j, k] in all_edges and [k, n] in all_edges:
....:             ok = False
....:             break
....:     if ok:
....:         edges.append( edge )
....:         

... and the di(rected )graph for the above labels and edges is:

sage: pos = { 0 :[ 0, 0], 
....:         1 :[ 2,-4],  2:[ 2,-2],  3:[ 2,0], 4:[2,2], 5:[2,4],
....:         6 :[ 5,-1],  7:[ 5, 1],
....:         8 :[ 6,+2],  9:[ 6, 0], 10:[ 6,-2],
....:         11:[11,+2], 12:[11, 0], 13:[11,-2],
....:         14:[14, 0] }
sage: D = DiGraph( [labels, edges], format='vertices_and_edges', pos=pos )
sage: D.show()
Launched png viewer for Graphics object consisting of 40 graphics primitives

And the tree is (with the root on the right side, corresponding to the full group, and the leaf on the left side, corresponding to its trivial subgroup):

The labels correspond to the index in the list of the groups, as listed above. The positions were chosen to reflect the orders in vertical levels. The level of groups of order four was splitted in two sublevels corresponding to the structure $C_2\times C_2$ (two cases, labels $6,7$), and respectively $C_4$, three cases, $8,9,10$.

The only arrows that need a check are those passing (or missing) from order $8$ to order $4$. The checks can be done by using the explicit generators.

---

If this kind of enumerative answer supported by computer (as typing resource rather) is not wanted, please ignore.