How to plot this problem? From Greek Exams

Question

Let's have $a_0$, $a_1$, $a_2$ complex numbers which are on the circle $(x-2)^2 +y^2=1$ (so for all of them the abs$\leq 3$ $\left|a_0\right|\leq3$, $\left|a_1\right|\leq3$, $\left|a_2\right|\leq3$). Let's have $v$ another complex number, and suppose that $v^3+a_2v^2+a_1v+a_0=0$. We must prove that $\left|v\right|<4$. The mathematical solusion is easy: $$\left|v^3\right|\leq3(\left|v\right|^2+\left|v\right|+1)\implies\left|v^3\right|-1\leq3(\left|v\right|^2+\left|v\right|+1)-1\implies\dots\implies\left|v\right|-1<3\\ \implies\left|v\right|<4$$ I'm asking if there is a way to plot the curve $v^3+a_2v^2+a_1v+a_0=0$ and show with the plot that $\left|v\right|<4$ in all cases. Thanks for your time

Answer 1

Since there is no straightforward approach to plotting "curves" depending on three parameters one can use Manipulate with three controls. We have three complex numbers a0, a1, a2 but since they lie on an appropriate circle we can parametrize them by three real parameters u1, u2, u3. Next we have to express solutions to the equation v^3 + a2 v^2 + a1 v + a0 == 0, we can do it with
Root[#^3 + (2 + Exp[I u3]) #^2 + (2 + Exp[I u2]) # + (2 + Exp[I u1]) &, 2]] where we substitute a0 by 2 + Exp[I u1], a1 by 2 + Exp[I u2] etc.

Now we have

Manipulate[
   Show[
     ContourPlot[{ (x - 2)^2 + y^2 - 1 == 0, x^2 + y^2 - 16 == 0},
                 {x, -4, 4}, {y, -4, 4}, Axes -> True, 
                 ContourStyle -> {{Thick, Blue}, {Thick, Darker@Green}}, 
                 AxesStyle -> Arrowheads[0.07]], 

     Graphics[{ 
       Table[{k[[1]], PointSize[0.02],
                      Point[{2 + Re[Exp[I k[[2]]]], Im[Exp[I k[[2]] ]]}]},

             {k, {{Red, u1}, {Darker@Green, u2}, {Darker@Orange, u3}}}], 
       Table[{k[[1]], PointSize[0.03], Point[{Re@#, Im@#} &@
              Root[#^3 + (2 + Exp[I u3]) #^2 + (2 + Exp[I u2]) # + (2 + Exp[I u1]) &,
                   k[[2]]]]},
             {k, {{Blue, 1}, {Magenta, 2}, {Darker@Cyan, 3}}}]}]], 

              {u1, 0, 2 Pi}, {u2, 0, 2 Pi}, {u3, 0, 2 Pi}]

Now this becomes evident that all the solutions represented by blue, magenta and cyan points satisfy Abs[v] < 4, in other words they lie in the green circle.