Implicit 3d plot with depending bounds

Question

I would like to plot this plane ($k1,k2,k3$ are constants):

$x-k1=0$ such as $x=k1..n$ ; $y=(z-k3+k2)..n $; $z=k3..n$

The difficulty is that second variable y depend on z. I was trying to use Maple implicitplot3d function, but I don't see a way.

Is it possible to use Maple for such plot ? If so, how ?

Answer 1

I don't think that you need to resort to an implicit plotting method for this (which can involve solving an implicit representation repeatedly to try and find the border on the fly, and which can result in a rendering with irregular edges or a need to mess with grid resolution).

It seems to me that you have an explicit formulation already, and using such you should be able to use the simple plot3d command and get a nice sharply displayed region without having to worry about mesh refinement or any advanced implicit plotting option.

But you may first have to realize that the 3 axes of the usual plot3d command are just first, second, and third axes and are not specifically named or labelled by names x, y, and z. The names you use to label the three axes can be chosen by you.

So, if I have understood your notation, let's use dummy names a and b for the first two axes (representing the independent variables in an explicit formulation).

Note that the range for the first independent variable can depend upon the name of the second independent variable. This allows for a clean and sharp tiling of the surface.

I use "a" for the "y" axis, and "b" for the "z" axis. I also add the labels option to specify the labels for the axes in the final display. I choose to label the first ("a") axis as "y", the second ("b") axis as "z", and the third (dependent) axis as "x".

restart:

k1,k2,k3,n := 3,5,8,10:

P:=plot3d(k1, a = b-k3+k2..n, b = k3..n, labels=["y","z","x"], view=k1..n):

plots:-display(P);

Now, you could also use the orientation option to reorient the above plot however you choose. You could specify an orientation in which the axis labelled "x" is vertical, or not. Your choice.

You might also want to switch around the axes, after the fact, so that the second axis above (labelled "z", but representing the second independent variable) is oriented vertically. By this I mean transforming the computed plot structure itself, rather than merely changing the orientation in which it gets rendered. This could be useful if you wished to display the plot combined some other plot.

I'll transform the whole structure in a few steps. You could display the result of each step if you wish to see the various effects. I'll just display the final structure.

P2:=plottools:-rotate(P,0,0,Pi/2):
P3:=plottools:-transform((a,b,c)->[a,-b,c])(P2):
P4:=plots:-display(P3,labels=[z,y,x]):

plots:-display(P4,view=[default,default,k1..n]);

Even if I haven't hit exactly what you were after, I hope it at least shows that you can likely get your result without having to resort to an implicit plotting method. There's a lot of flexibility, and you did not state how you wanted the results oriented or whether you wished to merge the plot with something else.