integral solutions of polynomials in two variables

Question

Consider the polynomial $$ 27x^4 - 256 y^3 = k^2, $$ where $k$ is an integer. As $k$ varies over all positive integers, is it possible to show that there are infinitely many distinct integral solutions $(X,Y,k)$?

There exists at least one solution: $x=12, y=-9, k=864$.

NOTE: If $(X,Y,k)$ is a solution then it is clear that $(\lambda^3X, \lambda^4 Y, \lambda^6 k)$ is also a solution. We will not consider such solutions to be distinct.

Answer 1

I will be modest and let $x$ be the constant $12$. I am looking for rational solutions, if such a solution will be found, we can adjust to an integer solution of the given equation...

We write the given equation in the form: $$ 2^4k^2 = (-2^4y)^3 + 27\cdot(2\cdot 12)^4\ . $$ There are too many features distracting the attention, so let us write simpler: $$ \tag{$\bbox[yellow]*$} \bbox[yellow]{\qquad Y^2 = X^3 + 8957952 \qquad} \ . $$ This is an elliptic curve or rank one, so it has infinitely many solutions. (The point we know is not a torsion point. It is enough to compute some of its multiples till it has no longer integral components.) Each solution is of the shape $(X,Y)=(a/c^2,\ b/c^3)$, so we obtain: $$ a^2 = b^3+ 27\cdot (2\cdot 12)^4\cdot c^6\ . $$ Multiply now with $c^6$ times a convenient power of two to get a solution for the initial equation.

$\square$

---

Example: We have done the theoretical job, but how does it work in practice?

The / a generator of $E$ is $P=(144, 3456)$. We compute on the elliptic curve for illustration $$ 5P= \left( \ \frac{478129063824}{64951^2}\ ,\ \frac{884224300107729024}{64951^3}\ \right)\ . $$ So $$ \scriptstyle \begin{aligned} 884224300107729024^2 \ &= \ 478129063824^3 \ + \ 27\cdot24^4\cdot 64951^6\ ,\\ (2^7\cdot 6908002344591633)^2 \ &=\ (2^4\cdot 29883066489)^3 \ + \ 27\cdot24^4\cdot 64951^6\ ,\\ \underbrace{2^8 \cdot(2^7\cdot 6908002344591633\cdot 64951^3)^2}_{=k^2} \ &= \ \underbrace{ 2^8\cdot (2^4\cdot 29883066489\cdot 64951^2)^3}_{=-256y^3} \ + \ \underbrace{ 2^8\cdot27\cdot24^4\cdot (64951^3)^4}_{=27x^4}\ . \end{aligned} $$ Computer check:

k = 2^4 * 2^7* 6908002344591633 * 64951^3
y = -2^4 * 29883066489 * 64951^2
x = 2^2 * 24 * 64951^3

print(f'{x = }')
print(f'{y = }')
print(f'{k = }')
print(f'Is 27 x^4 - 256 y^3 equal to k^2? {27*x^4 - 256*y^3 == k^2}.')

x = 26304421735425696
y = -2017050760507723361424
k = 3876501483124220154675766075766784
Is 27 x^4 - 256 y^3 equal to k^2? True.

And this is definitively not obtained from the initial solution, new primes appear:

sage: factor(x)
2^5 * 3 * 64951^3
sage: factor(y)
-1 * 2^4 * 3^2 * 239 * 1619 * 8581 * 64951^2
sage: factor(k)
2^11 * 3^3 * 179 * 61469 * 64951^3 * 23253029

---

---

The following code produces some first solutions of the given equation from the rank one elliptic curve given by the equation $\bbox[yellow]{(*)}$, the code is sage code.

E = EllipticCurve([0, 8957952])
r = E.rank()
P = E.gens()[0]
print(f'E is the elliptic curve:\n{E}')
print(f'It has rank {r}, generator {P.xy()}')

Results:

E is the elliptic curve:
Elliptic Curve defined by y^2 = x^3 + 8957952 over Rational Field
It has rank 1, generator (144, 3456)

Let us produce (primitive) solutions from $nP$ for $n$ from one to ten. I am also adjusting the sign for $x,k$ to be always plus.

ok = True    # so far
for n in [1..10]:
    X, Y = (n*P).xy()
    a, b, c = X.numerator(), Y.numerator(), ZZ(sqrt(X.denominator()))
    k, y, x = abs(2^4*b*c^3), -a*c^2, abs(2^2*24*c^3)
    for p in lcm([k, x, y]).prime_divisors():
        while (p^6).divides(k) and (p^4).divides(y):
            k, y, x = ZZ(k/p^6), ZZ(y/p^4), ZZ(x/p^3)
    print(r'$$\scriptstyle\left\{\begin{aligned}')
    print(f'x &= {x} \\\\ y &= {y} \\\\ k &= {k}')
    print(r'\end{aligned}\right.$$')
    
    ok = ok and (27*x^4 - 256*y^3 == k^2)    

And we obtain latex code, that gets interpreted to:

$$\scriptstyle\left\{\begin{aligned} x &= 12 \\ y &= -9 \\ k &= 864 \end{aligned}\right.$$ $$\scriptstyle\left\{\begin{aligned} x &= 96 \\ y &= 207 \\ k &= 4752 \end{aligned}\right.$$ $$\scriptstyle\left\{\begin{aligned} x &= 26364 \\ y &= -316537 \\ k &= 4600342240 \end{aligned}\right.$$ $$\scriptstyle\left\{\begin{aligned} x &= 1022208 \\ y &= -11067868548 \\ k &= 18630134476322688 \end{aligned}\right.$$ $$\scriptstyle\left\{\begin{aligned} x &= 3288052716928212 \\ y &= -126065672531732710089 \\ k &= 60570335673815939916808844933856 \end{aligned}\right.$$ $$\scriptstyle\left\{\begin{aligned} x &= 59092397452297092000 \\ y &= 105551827489081662313594775 \\ k &= 5307918169253382199287355371362715854000 \end{aligned}\right.$$ $$\scriptstyle\left\{\begin{aligned} x &= 684854186342049368537157007692 \\ y &= -2948299571951402381523622152177418224009 \\ k &= 3535584303812582851469882294132364605472798214196700963302496 \end{aligned}\right.$$ $$\scriptstyle\left\{\begin{aligned} x &= 67909710157557636005883183922173696 \\ y &= -744492746691722729563076508837193265604068766753 \\ k &= 10278077059182304649135759634892206566443721831738488224507780658646320368 \end{aligned}\right.$$ $$\scriptstyle\left\{\begin{aligned} x &= 543415149821931195491252431214155564246735673124 \\ y &= -850726959533330406055914028018101415179960629084921034229921977 \\ k &= 1584953169635431670648917828328221974349497854339127634592272304217992939828494785297931782115680 \end{aligned}\right.$$ $$\scriptstyle\left\{\begin{aligned} x &= 440549685267196503389525073244884545414860652952488929938144 \\ y &= 14567563540893092615611914024375396216952988466531381214049432285382018280456887 \\ k &= 475019900116901101109432937396478669864087400180086553530895568332610429307370864130180980872451352164679221622923404368 \end{aligned}\right.$$

Answer 2

The LHS $\,27x^4 - 256 y^3 = -\Delta\,$ where $\,\Delta = \prod_{i \ne j} (t_i-t_j)^2\,$ is the discriminant of the cubic $\,t^3 - 4 y t + x^2\,$ with roots $\,t_i\,$. Every such cubic with an integer root and a pair of complex conjugate Gaussian integer roots will provide a solution to the problem.

For example, the cubic with roots $\,t_1 = -8\,$, $\,t_{2,3} = 4 \pm 4 i\,$ is $\,t^3 - 32 t + 256\,$, corresponding to $\,y = 8\,$, $\,x = 16\,$. Its discriminant is $\,\Delta = -1638400 = -1280^2\,$, corresponding to $\,k = 1280\,$, which gives the solution $\,(x,y,k)=\left(16, 8, 1280\right)\,$.

For another example, the cubic $\,t^3 - 156 t + 1600\,$ with roots $\,t_1 = -16, t_{2,3} = 8 \pm 6i\,$ gives the solution $\,(x,y,k)=\left(40, 39, 7344\right)\,$.

This is a sufficient condition, though not a necessary one, for example OP's solution $\,x=12\,$, $\,y=-9\,$, $\,k = 864\,$ corresponds to the cubic $\,t^3 + 36 t + 144\,$ with $\,\Delta = -864^2\,$ even though none of its roots is a (Gaussian) integer.

---

[ EDIT ] $\;$ This cubic construction allows generating an infinite family of independent solutions to the problem (even though it is not the complete set of solutions, as noted).

Let $\,a^2+b^2=c^2\,$ be a Pythagorean triple with $\,a = 2mn\,$, $\,b=m^2-n^2\,$, $\,c=m^2+n^2\,$ where $\,m,n\,$ have the same parity and $\,mn\,$ is a perfect square. Then the cubic with roots $\,t_1=-2a\,$, $\,t_{2,3}=a \pm i b\,$ is:

$$t^3 - (3 a^2 - b^2) t + 2 a(a^2 + b^2) = t^3 - \left(12m^2n^2-(m^2-n^2)^2\right)t + 4 m n(m^2+n^2)^2$$

The discriminant of the cubic is (courtesy WA):

$$ \Delta = -4 (m^6 + 33 m^4 n^2 - 33 m^2 n^4 - n^6)^2 $$

This gives the family of solutions (all values are integers, under the stated assumptions):

$$ \begin{align} x &= \pm 2 \sqrt{mn}\,(m^2+n^2) \\ y &= 3 m^2n^2 - \frac{1}{4}(m^2-n^2)^2 \\ k &= \pm 2 (m^6 + 33 m^4 n^2 - 33 m^2 n^4 - n^6) \end{align} $$