Is the ideal $J:=\langle -y^2+xz,x^5-z^3 \rangle$ prime in $\Bbb{C}[x,y,z]?$

Question

We want to prove that the ideal $J:=\langle -y^2+xz,x^5-z^3 \rangle$ is prime in $\Bbb{C}[x,y,z].$

My attempt. An informal thought is to take the equations $y^2-xz=0,\ x^5-z^3=0 \iff y^2=xz,\ x^5=z^3.$ From this we set $x=t^3,y=t^4,z=t^5.$

So, now we define the mapping $$\phi: \Bbb{C}[x,y,z]\longrightarrow \Bbb{C}[t^3,t^4,t^5],\\ f(x,y,z)\mapsto \phi(f(x,y,z)):=f(t^3,t^4,t^5).$$

It's not difficult to see that $\phi$ is an epimorphism with image $\mathrm{Im}\phi=\Bbb C[t^3,t^4,t^5].$ And $J\subseteq \ker\phi$.

Questions.

1) What about $\ker \phi \subseteq J$? An idea is to take the division algorithm, and from this to claim that if $f\in \ker \phi\implies f=(-y^2+xz)\cdot q_1+r_1$ with $r_1\in \ker\phi,\ f= (x^5-z^3)\cdot q_2+r_2$ with $r_2\in \ker\phi$. But could this help?

2) If $J=\ker\phi,$ then (from 1st Isomorphism Theorem) $$\Bbb C[x,y,z]/\langle -y^2+xz,x^5-z^3 \rangle \cong \Bbb C[t^3,t^4,t^5] \subset \Bbb C [t],$$

so, $$\begin{equation} \begin{split}\Bbb C [t] \text{ is an integral domain }& \implies \Bbb C[t^3,t^4,t^5] \text{ is an integral domain } \\ & \iff \Bbb C[x,y,z]/\langle -y^2+xz,x^5-z^3\rangle \text{ is an integral domain} \\ & \iff J \text{ is prime ideal }. \end{split}\end{equation}$$ Is this claim right?

3) Are there any alternative proofs for 1) and 2) ?

Thank you in advance.

Answer 1

Note that sage does not confirm the primality of the given ideal.

sage: R.<x,y,z> = PolynomialRing(QQ)
sage: J = R.ideal( [ -y^2 + x*z, x^5 - z^3 ] )
sage: J
Ideal (-y^2 + x*z, x^5 - z^3) of Multivariate Polynomial Ring in x, y, z over Rational Field
sage: J.is_prime()
False
sage: J.primary_decomposition()
[Ideal (y^2 - x*z, x^2*y + z^2, x^3 + y*z) of Multivariate Polynomial Ring in x, y, z over Rational Field,
 Ideal (y^2 - x*z, x^2*y - z^2, x^3 - y*z) of Multivariate Polynomial Ring in x, y, z over Rational Field]
sage: J.primary_decomposition_complete()
[(Ideal (y^2 - x*z, x^2*y + z^2, x^3 + y*z) of Multivariate Polynomial Ring in x, y, z over Rational Field,
  Ideal (y^2 - x*z, x^2*y + z^2, x^3 + y*z) of Multivariate Polynomial Ring in x, y, z over Rational Field),
 (Ideal (y^2 - x*z, x^2*y - z^2, x^3 - y*z) of Multivariate Polynomial Ring in x, y, z over Rational Field, 
  Ideal (y^2 - x*z, x^2*y - z^2, x^3 - y*z) of Multivariate Polynomial Ring in x, y, z over Rational Field)
  ]

(The last result was adjusted manually.)

---

Later edit: To obtain some counterexamples we use the fact that $$ J = P\cap Q\ ,$$ where $P,Q$ are the above prime ideals offered by sage: $$ \begin{aligned} P &=\langle\ y^{2} - x z,\ x^{2} y + z^{2},\ x^{3} + y z\ \rangle\ ,\\ Q &=\langle\ y^{2} - x z,\ x^{2} y - z^{2},\ x^{3} - y z\ \rangle\ . \end{aligned} $$ The following code checks this situation.

sage: P, Q = J.primary_decomposition()
sage: P.intersection(Q) == J
True
sage: P.is_prime(), Q.is_prime()
(True, True)
sage: P.gens(), Q.gens()
([y^2 - x*z, x^2*y + z^2, x^3 + y*z], [y^2 - x*z, x^2*y - z^2, x^3 - y*z])

Now let us make the following choice of elements in the polynomial ring: $$ \begin{aligned} p &= x^{2} y + z^{2}\in P\ ,\\ q &= x^{2} y - z^{2}\in Q\ ,\\ &\qquad\text{ so the product $pq$ is in both $P$ and $Q$, i.e.}\\ pq&\in P\cap Q=J\ . \end{aligned} $$ This information is again lacking a "human argument", but we get closer:

sage: p, q = x^2*y + z^2, x^2*y - z^2
sage: p in P, q in Q
(True, True)
sage: p*q in J, p in J, q in J
(True, False, False)

sage: (p*q).lift(J)
[-x^4, z]
sage: p*q == -x^4*(-y^2 + x*z) + z*(x^5 - z^3)
True

This is the counterexample, sage gave us also the "lift" of $pq$ in terms of the generators of $J$, and now we have to show "humanly" that $p\not \in J$ and $q\not \in J$. So assume that there would be a representation $$ x^2y\pm z^2 =S(-y^2+xz)+T(x^5-z^3)\ . $$ Then it is impossible to produce $z^2$ by using the monomials $y^2,xz;x^5, z^3$ (multiplied by some other monomials). Contradiction. The assumption is false.

---

Note: In my answers i always try to deliver all details that were leading to the final solution. From the above, one can extract the simple argument in some lines, but "working in the ring" is more important, and this full experience may show fruitful next time.

Answer 2

Note that $J$ is not a prime ideal because $x^4-y^3,x^4+y^3\notin J$ but that $$(x^4-y^3)(x^4+y^3)=x^8-y^6=x^3(x^5-z^3)+(x^2z^2+xy^2z+y^4)(xz-y^2)\in J.$$