Is there a general formula for $\left [ \mathbb{Q}(a,b):\mathbb{Q}(a) \right ]$?

Question

I am trying to solve this problem which states as follows:

Find the minimum polynomial for $\sqrt[3]{4}+\sqrt{-27}$ over $\mathbb{Q}(\sqrt[3]{2})$ and $\mathbb{Q}(\sqrt{-3})$.

Here's what I have done so far (please correct me if I am wrong):

Since $\mathbb{Q}(\sqrt[3]{4})=\mathbb{Q}((\sqrt[3]{4})^{2})=\mathbb{Q}(\sqrt[3]{2})$, and $\mathbb{Q}(\sqrt{-27})=\mathbb{Q}(3\sqrt{-3})=\mathbb{Q}(\sqrt{-3})$, we have $\mathbb{Q}(\sqrt[3]{4}+\sqrt{-27})=\mathbb{Q}(\sqrt[3]{2},\sqrt{-3})$. And from the question, we would only need to calculate $\left [ \mathbb{Q}(\sqrt[3]{2},\sqrt{-3}):\mathbb{Q}(\sqrt[3]{2}) \right ]$ and $\left [ \mathbb{Q}(\sqrt[3]{2},\sqrt{-3}):\mathbb{Q}(\sqrt{-3}) \right ]$. Just wondering if there is a general way of solving degree of the form $\left [ \mathbb{Q}(a,b):\mathbb{Q}(a) \right ]$ which might make this easier?

Answer 1

Use Galois Theory. In our case, note that adjoining $\sqrt{-3}$ to $\Bbb Q$ is same as adjoining a primitive third root of unity, let this be $u=(-1+\sqrt{-3})/2$. So we indeed obtain a Galois extension of $\Bbb Q$ after adjoining $a=\sqrt[3]2$ and $b=\sqrt{-3}$. The fields in between are:

• degree $6$: $K=\Bbb Q(a,b)$,
• degree $3$: $L_0=\Bbb Q(a)$, $L_1=\Bbb Q(au)$, $L_2=\Bbb Q(au^2)$, all subfields of $K$, Galois index is $2=6:3$, for short $L_k=\Bbb Q(au^k)$, with $k=0,1,2$, and below we use tacitly $k$ having one of these values for this reason,
• degree $2$: $M=\Bbb Q(b)=\Bbb Q(-b)$
• degree $1$: $\Bbb Q$.

(Degrees are over $\Bbb Q$.)

Then we can experiment in sage, of course doing such computations with bare hands is not in conformity with the century... (i.e. using internet, stackexchange, but comuting with pencil and paper):

sage: R.<x> = QQ[]
sage: K.<a,b> = NumberField( [x^3-2, x^2+3])
sage: a^3 == 2, b^2 == -3
(True, True)
sage: a.absolute_minpoly(), b.absolute_minpoly()
(x^3 - 2, x^2 + 3)
sage: u = (-1+b)/2    # primitive 3.rd root of unity
sage: u^3
1
sage: [ (a*u^k).absolute_minpoly() for k in [0,1,2] ]
[x^3 - 2, x^3 - 2, x^3 - 2]
sage: (a^2+b^3).absolute_minpoly()
x^6 + 81*x^4 - 8*x^3 + 2187*x^2 + 648*x + 19699

sage: S.<Y> = K[]
sage: S
Univariate Polynomial Ring in Y over Number Field in a with defining polynomial x^3 - 2 over its base field
sage: prod( [ Y-(a*u^k)^2-(b*sgn)^3 for k in [0,1,2] for sgn in [-1,1] ] )
Y^6 + 81*Y^4 - 8*Y^3 + 2187*Y^2 + 648*Y + 19699

sage: prod( [ Y-(a*u^k)^2-b^3 for k in [0,1,2] ] )
Y^3 + 9*b*Y^2 - 81*Y - 81*b - 4

sage: prod( [ Y-a^2-(b*sgn)^3 for sgn in [-1,1] ] )
Y^2 - 2*a^2*Y + 2*a + 27

For short, the code considered the polynomial ring $S=K[Y]$, and computed first the polynomial obtained by building the product of $Y-c$, for all conjugates $c$ of $a^2+b^3$, which are of the shape $c=c_{k,\pm}:=(au^k)^2+(\pm b)^3$.

If we work over $M=\Bbb Q(b)$, then it is enough to take the product of $Y-c$ for $c$ of the shape $(au^k)^2+b^3$.

If we work over $M=\Bbb Q(a)$, then it is enough to take the product of $Y-c$ for $c$ of the shape $a^2+(\pm b)^3$.