Number of Partitioning a deck with m cards in n types into n-element sets.

Question

For exsample,

There are 2cards in 3type. AA,BB,CC.

Partition 6cards into 2 3-element sets.

[AAB,BCC],[AAC,BBC],[ABB,ACC],[ABC,ABC],... 4 ways

or

Partition 6cards into 3 2-element sets.

[AA,BB,CC],[AA,BC,BC],[AB,AB,CC],[AB,AC,BC],[AC,AC,BB],... 5 ways

I find that A002135 on oeis.org, 1,2,5,17,73,388,2461,..... is the number of ways that a deck with 2 cards of each of n types may be dealt into n hands of 2 cards each.

But I want to know how to count number of ways that a deck with m cards of each of n types maybe dealt into n hands of m cards each and maybe dealt into m hands of n cards each.

I programed and count some numbers several ways. But I can't know if what it's right.

Answer 1

Say the number of elements in each of the inner sets is $q.$ If I understand correctly we are working with the unlabeled species $$\mathfrak{M}_{=nm/q}(\mathfrak{M}_{=q}(\mathcal{Q}_1+ \mathcal{Q}_2+\mathcal{Q}_3+\mathcal{Q}_4+\cdots+\mathcal{Q}_n)).$$

It follows using the Polya Enumeration Theorem that the desired value is given by $$[Q_1^m Q_2^m Q_3^m \cdots Q_n^m] Z(S_{nm/q})(Z(S_q)(Q_1+Q_2+Q_3+\cdots+Q_n))$$ where $Z(S_q)$ is the cycle index of the symmetric group.

This formula is of moderate computational efficiency but it is exact. We get for two cards of $n$ types partitioned into $n$ hands of $2$ cards the sequence $$1, 2, 5, 17, 73, 388, 2461, 18155, \ldots$$ which is indeed OEIS A002135 as noted by the OP.

For $n$ types and three cards per hand we get the sequence $$1, 2, 10, 93, 1417, 32152, 1016489 \ldots$$

For $n$ types and four cards per hand we get the sequence $$1, 3, 23, 465, 19834, 1532489, 193746632\ldots$$

I suspect there is something better that can be done, in which case the above values can at least serve as proof of correctness.

If instead we fix the number of types we get for two types and two cards per hand $$1, 2, 2, 3, 3, 4, 4, 5, 5, 6, 6, 7, 7, 8, 8, 9, \ldots $$ and for three types with three cards per hand $$1, 4, 10, 25, 49, 103, 184, 331, 554, 911, 1424, 2204, 3278,\ldots$$ and for four types with four cards per hand $$1, 10, 70, 465, 2505, 12652, 57232, 240481, 936785, 3428138,\ldots$$

This computation was done with the following Maple code:

pet_cycleind_symm :=
proc(n)
        local p, s;
        option remember;

        if n=0 then return 1; fi;

        expand(1/n*add(a[l]*pet_cycleind_symm(n-l), l=1..n));
end;

pet_varinto_cind :=
proc(poly, ind)
local subs1, subs2, polyvars, indvars, v, pot, res;

    res := ind;

    polyvars := indets(poly);
    indvars := indets(ind);

    for v in indvars do
        pot := op(1, v);

        subs1 :=
        [seq(polyvars[k]=polyvars[k]^pot,
             k=1..nops(polyvars))];

        subs2 := [v=subs(subs1, poly)];

        res := subs(subs2, res);
    od;

    res;
end;

q :=
proc(n, m, q)
option remember;
    local tgf, gf1, gf2, k, res;

    if n*m mod q <> 0 then return FAIL fi;

    tgf := add(cat(`Q`, k), k=1..n);

    gf1 := expand(pet_varinto_cind
                  (tgf, pet_cycleind_symm(q)));
    gf2 := expand(pet_varinto_cind
                  (gf1, pet_cycleind_symm(n*m/q)));

    res := gf2;
    for k to n do
        res := coeff(res, cat(`Q`, k), m);
    od;

    res;
end;