Let's consider $\mathbb{Z}_3[x]/(x^2 + x + 2)$, I want to find solutions of $X^2 + X + 2$ in this field.

Question

Let's consider $\mathbb{Z}_3[x]/(x^2 + x + 2)$. I want to answer the following questions:

1. Prove that $\mathbb{Z}_3[x]/(x^2 + x + 2)$ is a field
2. How many elements are there?
3. What is the order of $s$, where $s$ is the equivalence class of $x$.
4. Which are the multiplicative subgroups?
5. Which are the solution of $X^2 + X + 2$?

---

My Solution

1) $\mathbb{Z}_3[x]/(x^2 + x + 2)$ iff $x^2 + x + 2$ is irreducible. I choose $p = 2$ and apply Eisenstein criterion.

2) The elements in this field are of the form: $as + b$ with $a$ and $b$ in $\mathbb{Z}^3$, so there are 9 elements.

3) Applying Lagrange theorem, the order of s can be: 1,2,4,8, because the multiplicative subgroup has 8 elements. I try everything : $s^1 = s \neq 1$, $s^2 = s^2 \neq 1$.

To find $s^4$, I need to do the following operation: $$\frac{s^4}{s^2 + s + 2}$$ The result is not 1 so the only possible choice is 8.

4) The multiplicative subgroups can have order 1,2,4,8. I exclude the one with order 1 and with order 8 because they are the trivial one. How can I find the subgroups of order 2 and 4?

5) I know that a solution is s, because by definition $s^2 + s + 2 = 0$. If that is a solution, I can write: $$ (x-s)(x - \alpha) = 0$$ with $\alpha$ as another solution. By multiplying, I obtain that $s\alpha = 2$, so $\alpha = 2 * s^{-1}$, with $s^{-1} = s^{8}$.

Is that all right as a solution? Could someone expand on point 3)? I mean: how can I better describe the subgroups?

Answer 1

This answer is with a big probability not wanted as it is, but for the small probability it does i will risk it. It uses a computer aided path, sage, and all computations are clear. (Sage is thinking highly structural from a mathematical point of view, so all code can be digested by a mathematician without further knowledge of sage and/or python.)

(1) We construct once for all times the general field (GF) $F$ with $3^2$ elements, using the given "modulus" $X^2+X+2$.

sage: R.<X> = PolynomialRing( GF(3) )
sage: F.<x> = GF( 3^2, modulus=X^2+X+2 )
sage: R
Univariate Polynomial Ring in X over Finite Field of size 3
sage: F
Finite Field in x of size 3^2
sage: (X^2+X+2).is_irreducible()
True

To see humanly that the polynomial is irreducible, it is enough to see it has no linear factor, i.e. no root in $\Bbb F_3$. Plugging in $\pm 1$ we obtain $1\pm 1-1\ne 0$, plugging in $0$ we get $-1\ne 0$. No roots in $\Bbb F_3$. So the polynomial $X^2+X-1$ is irreducible.

(2)

sage: F.order()
9
sage: F.list()
[0, x, 2*x + 1, 2*x + 2, 2, 2*x, x + 2, x + 1, 1]

(3)

sage: x.multiplicative_order()
8

sage: for k in [1..8]:
....:     print "x^%s = %s" % ( k, x^k )
....:     
x^1 = x
x^2 = 2*x + 1
x^3 = 2*x + 2
x^4 = 2
x^5 = 2*x
x^6 = x + 2
x^7 = x + 1
x^8 = 1

sage: factor( X^4+1 )
(X^2 + X + 2) * (X^2 + 2*X + 2)

After seeing the above, it is easy to show the relation $x^4=-1$ in $\Bbb F_9$: $$ (X^2+X-1)(X^2-X-1)) = (X^2-1)^2-X^2= X^4 -2X^2-X^2+1 =X^4+1\ . $$ Since the order of $x$ divides $8=9-1=|F^\times|$, and it is not $4$, it is $8$.

(4) $x$ generates $\langle x\rangle=(F^\times, \cdot) \cong (\Bbb Z/8,+)$, each subgroup is cyclic.

• The trivial subgroup is $\langle 1\rangle$ and has one element.
• The multiplicative subgroup $ \langle -1\rangle=\langle x^4\rangle$ and has two elements.
• The multiplicative subgroup $ \langle x^2\rangle=\langle x^6\rangle$ and has four elements.
• The multiplicative subgroup $ \langle x\rangle=\langle x^3\rangle=\langle x^5\rangle=\langle x^7\rangle$ and has eight elements.

(5) Vieta, the sum of the roots is $-1$, or...

sage: (X^2+X-1).base_extend(F).factor()
(X + x + 1) * (X + 2*x)
sage: (X^2+X-1).base_extend(F).roots(multiplicities=False)
[2*x + 2, x]
sage: (X^2+X-1).roots(ring=F, multiplicities=False)
[2*x + 2, x]