On the radical of a certain ideal of sixteen variable polynomial ring, generated by the entries of certain matrices

Question

Consider the polynomial ring $R=\mathbb C[x_1,x_2,...,x_{16}]$, and set

$$X=\begin{pmatrix} x_1 &x_2&x_3 &x_4\\ x_5&x_6& x_7&x_8\\x_9&x_{10}&x_{11}&x_{12}\\x_{13}&x_{14}&x_{15}&x_{16}\end{pmatrix}.$$

Now, using these three matrices

$$L=\begin{pmatrix}0&-1&0&0\\1&0&0&0\\0&0&0&-1\\0&0&1&0 \end{pmatrix}$$ $$M=\begin{pmatrix}0&0&0&-1\\0&0&-1&0\\0&1&0&0\\1&0&0&0\end{pmatrix}$$ $$N=\begin{pmatrix}0&0&-1&0\\0&0&0&1\\1&0&0&0\\0&-1&0&0\end{pmatrix}$$

we create polynomials $f_i, g_i,$ and $h_i$ in the following way:

$$XLX^t-L=\begin{pmatrix} f_1 &f_2&f_3 &f_4\\ f_5&f_6& f_7&f_8\\f_9&f_{10}&f_{11}&f_{12}\\f_{13}&f_{14}&f_{15}&f_{16}\end{pmatrix}$$

$$XMX^t-M=\begin{pmatrix} g_1 &g_2&g_3 &g_4\\ g_5&g_6& g_7&g_8\\g_9&g_{10}&g_{11}&g_{12}\\g_{13}&g_{14}&g_{15}&g_{16}\end{pmatrix}$$

$$XNX^t-N=\begin{pmatrix} h_1 &h_2&h_3 &h_4\\ h_5&h_6& h_7&h_8\\h_9&h_{10}&h_{11}&h_{12}\\h_{13}&h_{14}&h_{15}&h_{16}\end{pmatrix}$$

Finally, let $I = (f_i, g_i, h_i)$ be the ideal generated by these $48$ polynomials. Then how to show that the radical of $I$, i.e. $\sqrt I$, is generated by twelve linear polynomials and one quadratic polynomial ?

I have no idea how to approach this problem; may be use Nullstelensatz ... ?

Please help

NOTE : All the matrices $L,M,N$ are orthogonal , so the three defining equations can be written as $(XL)(LX)^t=(XM)(MX)^t=(XN)(NX)^t=Id$. Now if we can find some pattern in $XL,LX,MX,XM,NX,XN$ then it could be helpful to find the zero set of the ideal $I$ ... Also $L,M,N$ are skew symmetric matrices and as @Balaji sb noted, $LM=-N$ ... this means $L,M,N$ works as the $i,j,k$ in the Quaternion ring ...

Answer 1

Too long for a comment. In M2:

R=QQ[x_1..x_16]
X=matrix {{x_1,x_2,x_3,x_4},{x_5,x_6,x_7,x_8},{x_9,x_10,x_11,x_12},{x_13,x_14,x_15,x_16}}
L=matrix {{0,-1,0,0},{1,0,0,0},{0,0,0,-1},{0,0,1,0}}
M=matrix {{0,0,0,-1},{0,0,-1,0},{0,1,0,0},{1,0,0,0}}
N=matrix {{0,0,-1,0},{0,0,0,1},{1,0,0,0},{0,-1,0,0}}
I=ideal(X*L*transpose(X)-L,X*M*transpose(X)-M,X*N*transpose(X)-N)
tex oo

$0,{x}_{2} {x}_{5}-{x}_{1} {x}_{6}+{x}_{4} {x}_{7}-{x}_{3} {x}_{8}+1,{x}_{2} {x}_{9}-{x}_{1} {x}_{10}+{x}_{4} {x}_{11}-{x}_{3} {x}_{12},{x}_{2} {x}_{13}-{x}_{1} {x}_{14}+{x}_{4} {x}_{15}-{x}_{3} {x}_{16},-{x}_{2} {x}_{5}+{x}_{1} {x}_{6}-{x}_{4} {x}_{7}+{x}_{3} {x}_{8}-1,0,{x}_{6} {x}_{9}-{x}_{5} {x}_{10}+{x}_{8} {x}_{11}-{x}_{7} {x}_{12},{x}_{6} {x}_{13}-{x}_{5} {x}_{14}+{x}_{8} {x}_{15}-{x}_{7} {x}_{16},-{x}_{2} {x}_{9}+{x}_{1} {x}_{10}-{x}_{4} {x}_{11}+{x}_{3} {x}_{12},-{x}_{6} {x}_{9}+{x}_{5} {x}_{10}-{x}_{8} {x}_{11}+{x}_{7} {x}_{12},0,{x}_{10} {x}_{13}-{x}_{9} {x}_{14}+{x}_{12} {x}_{15}-{x}_{11} {x}_{16}+1,-{x}_{2} {x}_{13}+{x}_{1} {x}_{14}-{x}_{4} {x}_{15}+{x}_{3} {x}_{16},-{x}_{6} {x}_{13}+{x}_{5} {x}_{14}-{x}_{8} {x}_{15}+{x}_{7} {x}_{16},-{x}_{10} {x}_{13}+{x}_{9} {x}_{14}-{x}_{12} {x}_{15}+{x}_{11} {x}_{16}-1,0,0,{x}_{4} {x}_{5}+{x}_{3} {x}_{6}-{x}_{2} {x}_{7}-{x}_{1} {x}_{8},{x}_{4} {x}_{9}+{x}_{3} {x}_{10}-{x}_{2} {x}_{11}-{x}_{1} {x}_{12},{x}_{4} {x}_{13}+{x}_{3} {x}_{14}-{x}_{2} {x}_{15}-{x}_{1} {x}_{16}+1,-{x}_{4} {x}_{5}-{x}_{3} {x}_{6}+{x}_{2} {x}_{7}+{x}_{1} {x}_{8},0,{x}_{8} {x}_{9}+{x}_{7} {x}_{10}-{x}_{6} {x}_{11}-{x}_{5} {x}_{12}+1,{x}_{8} {x}_{13}+{x}_{7} {x}_{14}-{x}_{6} {x}_{15}-{x}_{5} {x}_{16},-{x}_{4} {x}_{9}-{x}_{3} {x}_{10}+{x}_{2} {x}_{11}+{x}_{1} {x}_{12},-{x}_{8} {x}_{9}-{x}_{7} {x}_{10}+{x}_{6} {x}_{11}+{x}_{5} {x}_{12}-1,0,{x}_{12} {x}_{13}+{x}_{11} {x}_{14}-{x}_{10} {x}_{15}-{x}_{9} {x}_{16},-{x}_{4} {x}_{13}-{x}_{3} {x}_{14}+{x}_{2} {x}_{15}+{x}_{1} {x}_{16}-1,-{x}_{8} {x}_{13}-{x}_{7} {x}_{14}+{x}_{6} {x}_{15}+{x}_{5} {x}_{16},-{x}_{12} {x}_{13}-{x}_{11} {x}_{14}+{x}_{10} {x}_{15}+{x}_{9} {x}_{16},0,0,{x}_{3} {x}_{5}-{x}_{4} {x}_{6}-{x}_{1} {x}_{7}+{x}_{2} {x}_{8},{x}_{3} {x}_{9}-{x}_{4} {x}_{10}-{x}_{1} {x}_{11}+{x}_{2} {x}_{12}+1,{x}_{3} {x}_{13}-{x}_{4} {x}_{14}-{x}_{1} {x}_{15}+{x}_{2} {x}_{16},-{x}_{3} {x}_{5}+{x}_{4} {x}_{6}+{x}_{1} {x}_{7}-{x}_{2} {x}_{8},0,{x}_{7} {x}_{9}-{x}_{8} {x}_{10}-{x}_{5} {x}_{11}+{x}_{6} {x}_{12},{x}_{7} {x}_{13}-{x}_{8} {x}_{14}-{x}_{5} {x}_{15}+{x}_{6} {x}_{16}-1,-{x}_{3} {x}_{9}+{x}_{4} {x}_{10}+{x}_{1} {x}_{11}-{x}_{2} {x}_{12}-1,-{x}_{7} {x}_{9}+{x}_{8} {x}_{10}+{x}_{5} {x}_{11}-{x}_{6} {x}_{12},0,{x}_{11} {x}_{13}-{x}_{12} {x}_{14}-{x}_{9} {x}_{15}+{x}_{10} {x}_{16},-{x}_{3} {x}_{13}+{x}_{4} {x}_{14}+{x}_{1} {x}_{15}-{x}_{2} {x}_{16},-{x}_{7} {x}_{13}+{x}_{8} {x}_{14}+{x}_{5} {x}_{15}-{x}_{6} {x}_{16}+1,-{x}_{11} {x}_{13}+{x}_{12} {x}_{14}+{x}_{9} {x}_{15}-{x}_{10} {x}_{16},0$

Edit

radical I -- Too many heap sections: Increase MAXHINCR or MAX_HEAP_SECTS

What @Youngsu suggests in a comment, does seem to work:

J=prune I
associatedPrimes J

$\langle x_{12}+x_{15},x_{11}-x_{16},x_{10}+x_{13},x_9-x_{14},x_8+x_{14},x_7-x_{13},x_6-x_{16},x_5+x_{15},x_4+x_{13},x_3+x_{14},x_2-x_{15},x_1-x_{16},x_{13}^2+x_{14}^2+x_{15}^2+x_{16}^2-1\rangle$

Answer 2

This is a full answer if a computer aided approach is welcome, else only some observations about elements in the ideal, here $J$ (instead of $I$), that may be useful for a human insight.

---

sage code performing the computation, let us see first the generators of $J$:

sage: R = PolynomialRing(QQ, ['x%s' % k for k in [1..16] ])
sage: R.gens()
(x1, x2, x3, x4, x5, x6, x7, x8, x9, x10, x11, x12, x13, x14, x15, x16)
sage: X = matrix(R, 4, 4, R.gens())
sage: X
[ x1  x2  x3  x4]
[ x5  x6  x7  x8]
[ x9 x10 x11 x12]
[x13 x14 x15 x16]

sage: L = matrix(QQ, 4, 4, [0,-1,0,0, 1,0,0,0, 0,0,0,-1, 0,0,1,0])
sage: M = matrix(QQ, 4, 4, [0,0,0,-1, 0,0,-1,0, 0,1,0,0, 1,0,0,0])
sage: N = matrix(QQ, 4, 4, [0,0,-1,0, 0,0,0,1, 1,0,0,0, 0,-1,0,0])

sage: J = R.ideal( (X*L*X.transpose()-L).list() +
....:              (X*M*X.transpose()-M).list() +
....:              (X*N*X.transpose()-N).list() )
sage: radJ = J.radical()

sage: radJ
Ideal (x12 + x15, x11 - x16, x10 + x13, x9 - x14, x8 + x14, x7 - x13, x6 - x16, x5 + x15,
       x4 + x13, x3 + x14, x2 - x15, x1 - x16, x13^2 + x14^2 + x15^2 + x16^2 - 1)
of Multivariate Polynomial Ring
in x1, x2, x3, x4, x5, x6, x7, x8, x9, x10, x11, x12, x13, x14, x15, x16
over Rational Field

sage: J.groebner_basis()
[x13^2 + x14^2 + x15^2 + x16^2 - 1, x1 - x16, x2 - x15, x3 + x14,
 x4 + x13, x5 + x15, x6 - x16, x7 - x13, x8 + x14, x9 - x14, x10 + x13,
 x11 - x16, x12 + x15]

sage: J == radJ
True

(Output was manually adjusted to fit in page.)

Above we have the generators / the Groebner basis of $J$.

Since the code was already written, here are some further elements of $J$:

sage: x1, x2, x3, x4, x5, x6, x7, x8, x9, x10, x11, x12, x13, x14, x15, x16 = R.gens()
sage: x1^2 + x2^2 + x3^2 + x4^2 - 1 in J
True
sage: x5^2 + x6^2 + x7^2 + x8^2 - 1 in J
True
sage: x9^2 + x10^2 + x11^2 + x12^2 - 1 in J
True
sage: x13^2 + x14^2 + x15^2 + x16^2 - 1 in J
True
sage: x1^2 + x5^2 + x9^2 + x13^2 - 1 in J
True
sage: x2^2 + x6^2 + x10^2 + x14^2 - 1 in J
True
sage: x3^2 + x7^2 + x11^2 + x15^2 - 1 in J
True
sage: x4^2 + x8^2 + x12^2 + x16^2 - 1 in J
True

And also, a double loop over the transcendental variables show that the following elements are in $J$:

x2 + x5
-x1 + x6
x4 + x7
-x3 + x8
x3 + x9
x8 + x9
-x4 + x10
x7 + x10
-x1 + x11
-x6 + x11
x2 + x12
-x5 + x12
x4 + x13
-x7 + x13
x10 + x13
x3 + x14
x8 + x14
-x9 + x14
-x2 + x15
x5 + x15
x12 + x15
-x1 + x16
-x6 + x16
-x11 + x16

I was trying to see the coefficients of each of the above linear elements $x_j\pm x_k$, in some cases there were many complicated coefficients needed, but sometimes there were simpler linear combinations. For instance:

sage: f1, f2, f3, f4, f5, f6, f7, f8, f9, f10, f11, f12, f13, f14, f15, f16, \
....: g1, g2, g3, g4, g5, g6, g7, g8, g9, g10, g11, g12, g13, g14, g15, g16, \
....: h1, h2, h3, h4, h5, h6, h7, h8, h9, h10, h11, h12, h13, h14, h15, h16, \
....: = J.gens()

sage: f3*x14 - f4*x10 + f7*x13 - f8*x9 + f12*(x2+x5) -g3*x16 + g4*x12 - g12*x4 - h7*x16 + h8*x12 - h12*x8
x2 + x5

sage: -g2*x15 + g4*x7 - g8*x3 - h2*x16 + h4*x8 - h8*x4
x4 + x7

sage: -g2*x11 + g3*x7 - g7*x3 - h2*x12 + h3*x8 - h7*x4
-x3 + x8

sage: f7*x15 - f8*x11 + f12*x7 + g2*x15 - g4*x7 + g8*x3 + h2*x16 - h4*x8 + h7*x14 + h8*(x4-x10) + h12*x6
-x4 + x10

sage: f7*x15 - f8*x11 + f12*x7 + h7*x14 - h8*x10 + h12*x6
x7 + x10

sage: -g2*x15 + g4*x7 - g8*x3 - h2*x16 + h4*x8 - h8*x4
x4 + x7

and many other.

I have to stop here, since i cannot see any structural way to face the problem.