What are the transformation equations for a curved cylindrical coordinate?

Question

What are the transformation equations $r=r(x,y), \phi=\phi(x,y)$ to define a coordinate system shown in the picture below.

As you can see, this is essentially a polar coordinate system with radial having an additional dependence on angle $\phi$ in such a way that radial isosurfaces represent round-apex triangles.

Answer 1

In general, given the function $F : \mathbb{R}^2 \to \mathbb{R}$ of law: $$ F(x,\,y) := \sum_{m = 1}^n \left|x\,\cos\left(2m\frac{\pi}{n}\right) + y\,\sin\left(2m\frac{\pi}{n}\right) - \frac{1}{n}\right|^k $$ with $k \in \mathbb{R}$, $n \in \mathbb{N}$ and $k \ge 2$, $n \ge 3$ fixed, the graph of the set of the points: $$ F(x,\,y) = 1 $$ in the limit case where $k = \infty$ is a regular polygon of center the origin of the axes, with radius of the inscribed circumference equal to $R = 1-\frac{1}{n}$, therefore with $n$ sides of length $L_p = 2\,R\,\tan\left(\frac{\pi}{n}\right)$ and with a side parallel to the y-axes. Decreasing $k$ gives the respective polygons with round edges, up to degenerate in the limit case $k = 2$ in a circumference of radius $\sqrt{\frac{2R}{n}}$.

To obtain polygons with a side parallel to the x-axes and with unitary sides, it's sufficient to apply a rotation of $\frac{\pi}{2}$ and a deformation of $L_p$ parallel to the two Cartesian axes, thus defining the function: $$ f(x,\,y) := \sum_{m = 1}^n \left|L_p\,x\,\cos\left(2m\frac{\pi}{n}+\frac{\pi}{2}\right) + L_p\,y\,\sin\left(2m\frac{\pi}{n}+\frac{\pi}{2}\right) - \frac{1}{n}\right|^k\,. $$ In particular, for $n = 3$, the law of $f$ is reduced to the following: $$ f(x,\,y) = \left|\frac{4}{\sqrt{3}}\,y - \frac{1}{3}\right|^k + \left|2\,x + \frac{2}{\sqrt{3}}\,y + \frac{1}{3}\right|^k + \left|2\,x - \frac{2}{\sqrt{3}}\,y - \frac{1}{3}\right|^k $$

f[x_, y_] := RealAbs[4 y/Sqrt[3] - 1/3]^k + 
             RealAbs[2 x + 2 y/Sqrt[3] + 1/3]^k + 
             RealAbs[2 x - 2 y/Sqrt[3] - 1/3]^k

and the graph of the set of the points: $$ f(x,\,y) = 1 $$

ContourPlot[Evaluate[Table[f[x, y] == 1, {k, Union[Range[2, 5], {200}]}]], 
            {x, -0.6, 0.6}, {y, -0.6, 0.6}, PlotPoints -> 100, 
            PlotLegends -> {"k = 2", "k = 3", "k = 4", "k = 5", "k = ∞"}]

turns out to be the following:

Specifically, we note that all the curves have the center in the origin of the axes and in the limit case $k = \infty$ an equilateral triangle of unitary side is obtained, while in the limit case $k = 2$ the corresponding inscribed circumference of radius $\frac{1}{L_p}\sqrt{\frac{2R}{n}} = \frac{\sqrt{3}}{6}$ is obtained.

Now, by way of example, fixed $k = 3$, the graph of the set of the points: $$ f\left(\frac{x}{L}, \; \frac{y}{L}\right) = 1 $$

k = 3;
ContourPlot[Evaluate[Table[f[x/L, y/L] == 1, {L, 1, 5}]], 
            {x, -2, 2}, {y, -2, 2}, PlotPoints -> 100, 
            PlotLegends -> {"L = 1", "L = 2", "L = 3", "L = 4", "L = 5"}]

with $L \in (0,\,\infty)$ fixed, turns out to be the following:

where $L$ corresponds to the measure of the side of the equilateral triangle obtainable with $k = \infty$.

The polar form of these plane curves, as usual, is of the type: $$(x,\,y) = \rho(\theta)\left(\cos\theta, \; \sin\theta\right) \quad \quad \theta \in [0,\,2\pi)$$ where $\rho = \rho(\theta)$ is the positive solution of the equation: $$f(\rho\,\cos\theta, \; \rho\,\sin\theta) = 1\,.$$ Unfortunately this equation is soluble only numerically and therefore it isn't possible to explicit the law $\rho = \rho(\theta)$, except for particular values of $k$.

On the other hand, referring to the particular case where $n = 3$, $k = 3$, $L = 1$, it's possible to tabulate the points of the corresponding curve by writing:

pts = Table[FindRoot[f[ρ Cos[θ], ρ Sin[θ]] == 1, 
            {ρ, 0.3}][[1, 2]] {Cos[θ], Sin[θ]}, 
            {θ, 0, 2 π, π/100}];

then processing these points through a Fourier analysis:

TrigFit[v_, m_, {x_, x0_, x1_}] := Module[{fc, fs, i, imax, j, n, p, t},
  n = Length[v]; imax = Min[m, Floor[(n - 1) / 2]]; t = 2 π (x - x0)/(x1 - x0);
  fc = Table[Sum[v[[j + 1]] Cos[2 π i j / n] / n, {j, 0, n - 1}], {i, 0, imax}];
  fs = Table[Sum[v[[j + 1]] Sin[2 π i j / n] / n, {j, 0, n - 1}], {i, 0, imax}];
  p = fc[[1]] + 2 Sum[fc[[i + 1]] Cos[i t] + fs[[i + 1]] Sin[i t], {i, 1, imax}];
  Expand@Rationalize[p, 0.001]]

paramF = TrigFit[#, 10, {t, 0, 2 π}]& /@ Transpose[pts]

we get:

{1/624 + (12 Cos[t])/37 - (2 Sin[t])/379 - 2/103 Sin[2 t] - 2/105 Sin[4 t], (2 Cos[t])/399 - 1/52 Cos[2 t] + 2/103 Cos[4 t] + (10 Sin[t])/31 - 2/973 Sin[4 t]}

ie: $$ \begin{cases} x(t) = -\frac{2\sin(t)}{379}-\frac{2}{103}\sin(2t)-\frac{2}{105}\sin(4t)+\frac{12\cos(t)}{37}+\frac{1}{624} \\ y(t) = \frac{10\sin(t)}{31}-\frac{2}{973}\sin(4t)+\frac{2\cos(t)}{399}-\frac{1}{52}\cos(2t)+\frac{2}{103}\cos(4t) \\ \end{cases} \quad \quad t \in [0,\,2\pi)\,. $$

In particular, by writing:

Show[ListLinePlot[pts, AspectRatio -> 1, PlotStyle -> Blue],
     ParametricPlot[paramF, {t, 0, 2 π}, PlotStyle -> Red]]

it's possible to appreciate the goodness of this approximation:

In conclusion, plotting the curves of parametric equations: $$(x,\,y) = L\cdot(x(t),\,y(t)) \quad \quad t \in [0,\,2\pi)$$

ParametricPlot[Evaluate[Table[L paramF, {L, 1, 5}]], {t, 0, 2 π}]

with $L \in (0,\,+\infty)$ fixed, we get:

which is very close to what is required.